1、深度睡眠

        ESP32 可以在不同的电源模式之间切换：

• 活动模式
• 调制解调器睡眠模式
• 浅睡眠模式
• 深度睡眠模式
• 休眠模式

         在深度睡眠模式下，CPU 或 Wi-Fi 活动都不会发生，但超低功耗 （ULP） 协处理器仍可打开电源，RTC 内存也会保持通电状态，因此我们可以为 ULP 编写程序并将其存储在 RTC 内存中，以访问外围设备、内部定时器和内部传感器。

        如果需要通过外部事件、计时器唤醒主 CPU，同时保持最小的功耗，则此操作模式非常有用。

        在深度睡眠期间，ULP 协处理器可以使用部分 ESP32 引脚，即 RTC_GPIO 引脚和 Touch 引脚。

        深度睡眠设置步骤：

1. 首先需要配置唤醒源，可以使用一个或组合多个唤醒源。
2. 可以决定在深度睡眠期间关闭或保持打开哪些外围设备。默认情况下，ESP32 会自动关闭定义的唤醒源不需要的外设。
3. 最后，使用 esp_deep_sleep_start() 将 ESP32 置于深度睡眠模式的功能。

---

2、唤醒源

        将 ESP32 置于深度睡眠模式后，有几种方法可以唤醒它：

• 使用计时器，使用预定义的时间段唤醒 ESP32;
• 使用触摸引脚;
• 使用外部唤醒：可以使用一种外部唤醒，也可以使用几种不同的外部唤醒;
• 使用 ULP 协处理器唤醒。

       

        进入睡眠函数：

esp_deep_sleep_start();

         返回唤醒原因函数：

esp_sleep_get_wakeup_cause();

---

3、定时器唤醒

        ESP32 RTC 控制器具有内置定时器，可用于在预定义的时间后唤醒 ESP32。

        ESP32 可以进入深度睡眠模式，然后在预定义的时间段唤醒。如果正在运行需要时间戳或日常任务的项目，同时保持低功耗，则此功能特别有用。
        启用定时器唤醒只需在以下函数中指定休眠时间（单位微秒）：esp_sleep_enable_timer_wakeup(time_in_us);

#include <Arduino.h>


// 使用定时器唤醒时，通电的部分是 RTC 控制器、RTC 外设和 RTC 存储器。

#define uS_TO_S_FACTOR 1000000  /* 微秒到秒的转换系数 */
#define TIME_TO_SLEEP  5        /* ESP32休眠时间(单位秒) */

RTC_DATA_ATTR int bootCount = 0;    // RTC 内存上定义深度睡眠中唤醒的次数 bootCount


// 唤醒原因
void print_wakeup_reason()
{
    esp_sleep_wakeup_cause_t wakeup_reason;

    wakeup_reason = esp_sleep_get_wakeup_cause();

    switch(wakeup_reason)
    {
        case ESP_SLEEP_WAKEUP_EXT0 : Serial.println("Wakeup caused by external signal using RTC_IO"); break;
        case ESP_SLEEP_WAKEUP_EXT1 : Serial.println("Wakeup caused by external signal using RTC_CNTL"); break;
        case ESP_SLEEP_WAKEUP_TIMER : Serial.println("Wakeup caused by timer"); break;
        case ESP_SLEEP_WAKEUP_TOUCHPAD : Serial.println("Wakeup caused by touchpad"); break;
        case ESP_SLEEP_WAKEUP_ULP : Serial.println("Wakeup caused by ULP program"); break;
        default : Serial.printf("Wakeup was not caused by deep sleep: %d\n",wakeup_reason); break;
    }
}


void setup()
{
    Serial.begin(115200);
    delay(2000);        // 打开串行监视器

    
    ++bootCount;    // 每次重新启动时计数
    Serial.println("Boot number: " + String(bootCount));

    print_wakeup_reason();      // 打印ESP32的唤醒原因

    esp_sleep_enable_timer_wakeup(TIME_TO_SLEEP * uS_TO_S_FACTOR);      // 配置唤醒源（微秒单位）
    Serial.println("Setup ESP32 to sleep for every " + String(TIME_TO_SLEEP) +" Seconds");


    Serial.println("Going to sleep now");
    delay(1000);
    Serial.flush(); 
    esp_deep_sleep_start();     // 进入睡眠
    Serial.println("This will never be printed");
}

void loop()
{
}

---

4、触摸唤醒

        启用触摸唤醒只需调用函数：

esp_sleep_enable_touchpad_wakeup();

#include <Arduino.h>


// 触摸引脚设置阈值
#if CONFIG_IDF_TARGET_ESP32
    #define THRESHOLD     40        /* 值越大，灵敏度越高 */
#else       // ESP32-S2 and ESP32-S3 + default for other chips (to be adjusted) */
    #define THRESHOLD     5000      /* 值越小，灵敏度越高 */
#endif

RTC_DATA_ATTR int bootCount = 0;    // RTC 内存上定义深度睡眠中唤醒的次数 bootCount
touch_pad_t touchPin;


// 唤醒原因
void print_wakeup_reason()
{
    esp_sleep_wakeup_cause_t wakeup_reason;

    wakeup_reason = esp_sleep_get_wakeup_cause();

    switch(wakeup_reason)
    {
        case ESP_SLEEP_WAKEUP_EXT0 : Serial.println("Wakeup caused by external signal using RTC_IO"); break;
        case ESP_SLEEP_WAKEUP_EXT1 : Serial.println("Wakeup caused by external signal using RTC_CNTL"); break;
        case ESP_SLEEP_WAKEUP_TIMER : Serial.println("Wakeup caused by timer"); break;
        case ESP_SLEEP_WAKEUP_TOUCHPAD : Serial.println("Wakeup caused by touchpad"); break;
        case ESP_SLEEP_WAKEUP_ULP : Serial.println("Wakeup caused by ULP program"); break;
        default : Serial.printf("Wakeup was not caused by deep sleep: %d\n",wakeup_reason); break;
    }
}


// 被唤醒的触摸 IO
void print_wakeup_touchpad()
{
    touchPin = esp_sleep_get_touchpad_wakeup_status();

    #if CONFIG_IDF_TARGET_ESP32
    switch(touchPin)
    {
        case 0  : Serial.println("Touch detected on GPIO 4"); break;
        case 1  : Serial.println("Touch detected on GPIO 0"); break;
        case 2  : Serial.println("Touch detected on GPIO 2"); break;
        case 3  : Serial.println("Touch detected on GPIO 15"); break;
        case 4  : Serial.println("Touch detected on GPIO 13"); break;
        case 5  : Serial.println("Touch detected on GPIO 12"); break;
        case 6  : Serial.println("Touch detected on GPIO 14"); break;
        case 7  : Serial.println("Touch detected on GPIO 27"); break;
        case 8  : Serial.println("Touch detected on GPIO 33"); break;
        case 9  : Serial.println("Touch detected on GPIO 32"); break;
        default : Serial.println("Wakeup not by touchpad"); break;
    }
    #else
        if(touchPin < TOUCH_PAD_MAX)
        {
            Serial.printf("Touch detected on GPIO %d\n", touchPin); 
        }
        else
        {
            Serial.println("Wakeup not by touchpad");
        }
    #endif
}


void setup()
{
    Serial.begin(115200);

    ++bootCount;    // 每次重新启动时计数
    Serial.println("Boot number: " + String(bootCount));

    print_wakeup_reason();      // 打印唤醒原因
    print_wakeup_touchpad();    // 打印触摸 IO

    #if CONFIG_IDF_TARGET_ESP32 
        //Setup sleep wakeup on Touch Pad 3 + 7 (GPIO15 + GPIO 27) 
        touchSleepWakeUpEnable(T3,THRESHOLD);
        touchSleepWakeUpEnable(T7,THRESHOLD);
    #else //ESP32-S2 + ESP32-S3
        //Setup sleep wakeup on Touch Pad 3 (GPIO3) 
        touchSleepWakeUpEnable(T3,THRESHOLD);
    #endif

    Serial.println("Going to sleep now");
    esp_deep_sleep_start();     // 进入睡眠
    Serial.println("This will never be printed");
}

void loop()
{
}