[SAP ABAP] ALV报表练习1

销售订单明细查询报表

业务目的：根据选择屏幕的筛选条件，使用 ALV 报表，显示销售订单详情

效果展示

用户的输入条件界面

用户的查询结果界面(部分截图)

完整代码如下所示 

主程序(zsd001_437)

*&---------------------------------------------------------------------*
*& Report ZSD001_437
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT zsd001_437.

INCLUDE zsd001_437_top. " 数据定义

INCLUDE zsd001_437_f01. " 子例程


*----------------------------------------------------------------------*
*  DESC: INITIALIZATION 事件
*----------------------------------------------------------------------*
INITIALIZATION.


*----------------------------------------------------------------------*
*  DESC: AT SELECTION-SCREEN OUTPUT 事件
*----------------------------------------------------------------------*
AT SELECTION-SCREEN OUTPUT.


*----------------------------------------------------------------------*
*  DESC: AT SELECTION-SCREEN  事件
*----------------------------------------------------------------------*
AT SELECTION-SCREEN.


*----------------------------------------------------------------------*
*  DESC: START-OF-SELECTION 事件
*----------------------------------------------------------------------*
START-OF-SELECTION.
  PERFORM frm_get_data.  " 获取数据


*---------------------------------------------------------------------*
* END-OF-SELECTION 事件
*---------------------------------------------------------------------*
END-OF-SELECTION.
  PERFORM frm_display_data.  " ALV呈现数据

INCLUDE程序(zsd001_437_top)

*&---------------------------------------------------------------------*
*& 包含               ZSD001_437_TOP
*&---------------------------------------------------------------------*

TABLES: vbak, vbap.

* 定义数据类型
TYPES: BEGIN OF ty_item,
      sel(1),                      " 选择标志
      vtext1   TYPE tvkot-vtext,   " 销售组织名称
      vtext2   TYPE tvtwt-vtext,   " 分销渠道名称
      bztxt    TYPE t171t-bztxt,   " 销售区域名称
      ktext    TYPE t151t-ktext,   " 客户组
      vtext3   TYPE tvktt-vtext,   " 账户分配组
      auart    TYPE vbak-auart,    " 订单类型
      bezei    TYPE tvakt-bezei,   " 订单类型描述
      vbeln    TYPE vbak-vbeln,    " 销售订单号
      kunnr    TYPE kna1-kunnr,    " 客户编号
      name1    TYPE kna1-name1,    " 客户名称
      audat    TYPE vbak-audat,    " 订单创建日期
      posnr    TYPE vbap-posnr,    " 行项目号
      matnr    TYPE mara-matnr,    " 物料编码
      maktx    TYPE makt-maktx,    " 物料名称
      kwmeng   TYPE vbap-kwmeng,   " 订单数量
      vrkme    TYPE vbap-vrkme,    " 订单单位
      werks    TYPE vbap-werks,    " 交货工厂
      fevor    TYPE marc-fevor,    " 生产管理员
      txt      TYPE t024f-txt,     " 生产主管姓名
      mbdat    TYPE vbbe-mbdat,    " 订单预交日期
      vbeln_fh TYPE c LENGTH 100,  " 发货单单号
      erdat    TYPE likp-erdat,    " 发货单创建日期
      lfimg    TYPE lips-lfimg,    " 申请发货数
      labst    TYPE mard-labst,    " 现有库存
      vgbel    TYPE vbap-vgbel,    " 合同号
      labor    TYPE mara-labor,    " 产品状态
      delqty   TYPE vbfa-rfmng,    " 发货数量
END OF ty_item.


DATA: gt_item TYPE STANDARD TABLE OF ty_item,  " 内表
      gs_item TYPE ty_item.                    " 结构体变量


* ALV参数定义
DATA: gs_layout TYPE  lvc_s_layo,                  " 用于定义ALV表单的相关格式、属性
      gs_fcat   TYPE  lvc_s_fcat,                  " 字段目录工作区
      gt_fcat   TYPE STANDARD TABLE OF lvc_s_fcat. " 字段目录内表


* 选择屏幕(屏幕输入)
SELECT-OPTIONS:
  s_vkorg FOR vbak-vkorg OBLIGATORY,   " 销售组织(必输)
  s_vtweg FOR vbak-vtweg,              " 分销渠道
  s_auart FOR vbak-auart,              " 销售订单类型
  s_vbeln FOR vbak-vbeln,              " 销售订单编号
  s_matnr FOR vbap-matnr.              " 物料编码

INCLUDE程序(zsd001_437_f01)

*&---------------------------------------------------------------------*
*& 包含               ZSD001_437_F01
*&---------------------------------------------------------------------*
*&---------------------------------------------------------------------*
*& Form frm_get_data
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_get_data.
  SELECT tvkot~vtext AS vtext1,                    " 销售组织名称
         tvtwt~vtext AS vtext2,                    " 分销渠道名称
         t171t~bztxt,                              " 销售区域名称
         t151t~ktext,                              " 客户组
         tvktt~vtext AS vtext3,                    " 账户分配组
         vbak~auart,                               " 订单类型
         tvakt~bezei,                              " 订单描述类型
         vbak~vbeln,                               " 销售订单号
         vbak~kunnr,                               " 客户编号
         kna1~name1,                               " 客户名称
         vbak~audat,                               " 订单创建日期
         vbap~posnr,                               " 行项目号
         vbap~matnr,                               " 物料编码
         makt~maktx,                               " 物料名称
         vbap~kwmeng,                              " 订单数量
         vbap~vrkme,                               " 订单单位
         vbap~werks,                               " 交货工厂
         marc~fevor,                               " 生产管理员
         t024f~txt,                                " 生产主管姓名
         vbap~vgbel,                               " 合同号
         mara~labor                                " 产品状态
    FROM vbak
    INNER JOIN vbap
    ON vbak~vbeln = vbap~vbeln

    LEFT JOIN tvkot
    ON vbak~vkorg = tvkot~vkorg
    AND tvkot~spras = @sy-langu

    LEFT JOIN tvtwt
    ON vbak~vtweg = tvtwt~vtweg
    AND tvtwt~spras = @sy-langu

    LEFT JOIN vbkd
    ON vbap~vbeln = vbkd~vbeln
    AND vbap~posnr = vbkd~posnr

    LEFT JOIN t171t
    ON vbkd~bzirk = t171t~bzirk
    AND t171t~spras = @sy-langu

    LEFT JOIN t151t
    ON vbkd~kdgrp = t151t~kdgrp
    AND t151t~spras = @sy-langu

    LEFT JOIN tvktt
    ON vbkd~ktgrd = tvktt~ktgrd
    AND tvktt~spras = @sy-langu

    LEFT JOIN tvakt
    ON vbak~auart = tvakt~auart
    AND tvakt~spras = @sy-langu

    LEFT JOIN kna1
    ON vbak~kunnr = kna1~kunnr

    LEFT JOIN makt
    ON vbap~matnr = makt~matnr
    AND makt~spras = @sy-langu

    LEFT JOIN marc
    ON vbap~werks = marc~werks
    AND vbap~matnr = marc~matnr

    LEFT JOIN t024f
    ON marc~fevor = t024f~fevor
    AND marc~werks = t024f~werks

    LEFT JOIN mara
    ON vbap~matnr = mara~matnr

  INTO CORRESPONDING FIELDS OF TABLE @gt_item
  WHERE vbak~vkorg IN @s_vkorg
    AND vbak~vtweg IN @s_vtweg
    AND vbak~auart IN @s_auart
    AND vbak~vbeln IN @s_vbeln
    AND vbap~matnr IN @s_matnr.

  IF sy-subrc = 0.
    PERFORM frm_edit_data.  " 编辑处理内表数据
  ENDIF.

ENDFORM.

*&---------------------------------------------------------------------*
*& Form frm_edit_data
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_edit_data.
  IF gt_item IS NOT INITIAL. " 当gt_item内表不为空时，进行以下逻辑处理

*    订单预交日期字段查询处理
     SELECT vbbe~vbeln,      " 销售凭证
            vbbe~posnr,      " 销售凭证项目
            vbbe~mbdat       " 订单预交日期
      FROM vbbe
      INTO TABLE @DATA(lt_vbbe)
      FOR ALL ENTRIES IN @gt_item
      WHERE vbeln = @gt_item-vbeln
        AND posnr = @gt_item-posnr.
    IF sy-subrc = 0.
      SORT lt_vbbe BY vbeln posnr mbdat.  " 对内表lt_vbbe中的字段vbeln，posnr和mbdat进行升序排序
    ENDIF.


*   发货单单号、发货单创建日期和申请发货数字段查询处理
    SELECT lips~vgbel,     " 参考单据的单据编号
           lips~vgpos,     " 参考项目的项目号
           lips~vbeln,     " 发货单单号
           lips~posnr,     " 交货项目
           lips~lfimg,     " 实际已交货量
           likp~erdat      " 记录建立日期
      FROM lips
      INNER JOIN likp
      ON lips~vbeln = likp~vbeln
      INTO TABLE @DATA(lt_lips)
      FOR ALL ENTRIES IN @gt_item
      WHERE vgbel = @gt_item-vbeln
        AND vgpos = @gt_item-posnr.
    IF sy-subrc = 0.
      SORT lt_lips BY vbeln posnr erdat DESCENDING.
      DATA(lt_max_erdat) = lt_lips.  " 赋值
      SORT lt_max_erdat BY vgbel vgpos erdat DESCENDING.
    ENDIF.


*   现有库存字段查询处理
    SELECT mard~werks,     " 工厂
           mard~matnr,     " 物料编号
           mard~labst      " 非限制使用的估价的库存
    FROM mard
    INTO TABLE @DATA(lt_mard)
    FOR ALL ENTRIES IN @gt_item
    WHERE matnr = @gt_item-matnr
      AND werks = @gt_item-werks.

  ENDIF.


  LOOP AT gt_item ASSIGNING FIELD-SYMBOL(<lfs_item>).  " 一条一条处理

    " 订单预交日期字段逻辑处理
    " 取最小的订单预交日期
    SELECT MIN( mbdat )
      FROM vbbe
      INTO <lfs_item>-mbdat
      WHERE vbeln = <lfs_item>-vbeln
        AND posnr = <lfs_item>-posnr.


    LOOP AT lt_lips INTO DATA(ls_lips)
      WHERE vgbel = <lfs_item>-vbeln AND vgpos = <lfs_item>-posnr .
      " 发货单单号字段逻辑处理
      IF ls_lips-vbeln IS NOT INITIAL.
        ls_lips-vbeln = |{ ls_lips-vbeln ALPHA = OUT }|.                    " 去除vbeln字段中的前导零
        <lfs_item>-vbeln_fh = <lfs_item>-vbeln_fh && ',' && ls_lips-vbeln.  " 如果出现多个交货单，则将交货单拼接显示 DN1,DN2,DN3
      ENDIF.
      " 申请发货数字段逻辑处理
      <lfs_item>-lfimg = <lfs_item>-lfimg + ls_lips-lfimg.  " 根据订单号进行行项目累加
    ENDLOOP.

    SHIFT <lfs_item>-vbeln_fh LEFT DELETING LEADING ','. " 删除首端的逗号


    " 发货单创建日期字段逻辑处理
    READ TABLE lt_max_erdat WITH KEY vgbel = <lfs_item>-vbeln vgpos = <lfs_item>-posnr
      INTO DATA(ls_max_erdat).
    IF sy-subrc = 0.
      <lfs_item>-erdat = ls_max_erdat-erdat.  " 取最大日期
    ENDIF.


    " 现有库存字段逻辑处理
    LOOP AT lt_mard INTO DATA(ls_mard)
      WHERE werks = <lfs_item>-werks AND matnr = <lfs_item>-matnr.
      <lfs_item>-labst = <lfs_item>-labst + ls_mard-labst.  " 累加所有库位的数量
    ENDLOOP.
  ENDLOOP.
ENDFORM.

*&---------------------------------------------------------------------*
*& Form frm_display_data
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_display_data.

  PERFORM frm_alv_set_fields.

  " 调用函数显示ALV数据
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
    EXPORTING
      i_bypassing_buffer       = abap_true
      i_callback_program       = sy-repid
      it_fieldcat_lvc          = gt_fcat                 " 设置ALV列属性
      is_layout_lvc            = gs_layout               " 设置ALV布局
      i_callback_pf_status_set = 'FRM_ALV_SET_STATUS'    " 子例程(设置状态栏)
      i_callback_user_command  = 'FRM_ALV_USER_COMMAND'  " 子例程(用户指令响应)
    TABLES
      t_outtab                 = gt_item                 " 内表数据
    EXCEPTIONS
      program_error            = 1
      OTHERS                   = 2.

ENDFORM.

*&---------------------------------------------------------------------*
*& Form frm_alv_set_fields
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM frm_alv_set_fields .
  DATA: lv_index LIKE sy-index.

  CLEAR: gs_fcat,
         gt_fcat,
         gs_layout.

* 设置行的属性(ALV界面格式)
  gs_layout-box_fname     = 'SEL'. " 选择标识
  gs_layout-zebra         = 'X'.   " 斑马条纹显示
  gs_layout-cwidth_opt    = 'X'.   " 优化列宽设置


* ALV字段处理宏
  DEFINE catalog.
    lv_index = lv_index + 1.
    gs_fcat-col_pos       = lv_index.
    gs_fcat-fieldname     = &1.  " 设置要输出的表格列的值，在内表中定义的字段名(必须大写)
    gs_fcat-fix_column    = &2.  " 固定列
    gs_fcat-ref_table     = &3.
    gs_fcat-edit          = &4.
    gs_fcat-colddictxt    = 'L'.
    gs_fcat-scrtext_l     = &5.  " 设置要输出的表格列的列名，即ALV报表显示的列名
    gs_fcat-ref_field     = &6.
    gs_fcat-outputlen     = &7.
    gs_fcat-emphasize     = &8.  " 列颜色
    gs_fcat-hotspot       = &9.  " 热点

    APPEND gs_fcat TO gt_fcat.
  END-OF-DEFINITION.

*     &1        &2        &3     &4          &5           &6      &7      &8     &9
  catalog:
    'VTEXT1'    'X'       ''     ''     '销售组织名称'     ''      ''      'C510' 'X',  " 销售组织名称
    'VTEXT2'    'X'       ''     ''     '分销渠道名称'     ''      ''      ''     '',   " 分销渠道名称
    'BZTXT'     ''        ''     ''     '销售区域名称'     ''      ''      ''     '',   " 销售区域名称
    'KTEXT'     ''        ''     ''     '客户组'           ''      ''      ''     '',   " 客户组
    'VTEXT3'    ''        ''     ''     '账户分配组'       ''      ''      ''     '',   " 账户分配组
    'AUART'     ''        ''     ''     '订单类型'         ''      ''      ''     '',   " 订单类型
    'BEZEI'     ''        ''     ''     '订单类型描述'     ''      ''      ''     '',   " 订单类型描述
    'VBELN'     ''        ''     ''     '销售订单号'       ''      ''      ''     '',   " 销售订单号
    'KUNNR'     ''        ''     ''     '客户编号'         ''      ''      ''     '',   " 客户编号
    'NAME1'     ''        ''     ''     '客户名称'         ''      ''      ''     '',   " 客户名称
    'AUDAT'     ''        ''     ''     '订单创建日期'     ''      ''      ''     '',   " 订单创建日期
    'POSNR'     ''        ''     ''     '行项目号'         ''      ''      ''     '',   " 行项目号
    'MATNR'     ''        'MARA' ''     '物料编码'         'MATNR' ''      ''     '',   " 物料编码
    'MAKTX'     ''        ''     ''     '物料名称'         ''      ''      ''     '',   " 物料名称
    'KWMENG'    ''        ''     ''     '订单数量'         ''      ''      ''     '',   " 订单数量
    'VRKME'     ''        ''     ''     '订单单位'         ''      ''      ''     '',   " 订单单位
    'WERKS'     ''        ''     ''     '交货工厂'         ''      ''      ''     '',   " 交货工厂
    'FEVOR'     ''        ''     ''     '生产管理员'       ''      ''      ''     '',   " 生产管理员
    'TXT'       ''        ''     ''     '生产主管姓名'     ''      ''      ''     '',   " 生产主管姓名
    'MBDAT'     ''        ''     ''     '订单预交日期'     ''      ''      ''     '',   " 订单预交日期
    'VBELN_FH'  ''        ''     ''     '发货单单号'       ''      ''      ''     '',   " 发货单单号
    'ERDAT'     ''        ''     ''     '发货单创建日期'   ''      ''      ''     '',   " 发货单创建日期
    'LFIMG'     ''        ''     ''     '申请发货数'       ''      ''      ''     '',   " 申请发货数
    'LABST'     ''        ''     ''     '现有库存'         ''      ''      ''     '',   " 现有库存
    'VGBEL'     ''        ''     ''     '合同号'           ''      ''      ''     '',   " 合同号
    'LABOR'     ''        ''     ''     '产品状态'         ''      ''      ''     '',   " 产品状态
    'DELQTY'    ''        ''     ''     '交货数量'         ''      ''      ''     ''.   " 交货数量
ENDFORM.


* 设置状态栏
FORM frm_alv_set_status USING ct_extab TYPE slis_t_extab.
  SET PF-STATUS 'ZSTALV' EXCLUDING ct_extab.
ENDFORM.


* 设置用户指令响应
FORM frm_alv_user_command USING pv_ucomm LIKE sy-ucomm
                                ps_selfield TYPE slis_selfield.

  ps_selfield-refresh = 'X'." 编辑完成保存后刷新alv页

  CASE pv_ucomm.  " pv_ucomm参数表示引发输入后处理的功能代码
    WHEN '&DIS'.  " 自定义按钮点击
      READ TABLE gt_item INTO gs_item INDEX ps_selfield-tabindex.
*     事件触发时显示当前行的销售订单号
      MESSAGE gs_item-vbeln TYPE 'I'.
    WHEN '&IC1'.  " 单击(热点)或者双击进行触发：单击和双击使用同一功能代码(用户命令执行)
      READ TABLE gt_item INTO gs_item INDEX ps_selfield-tabindex.
*     事件触发时显示当前行的销售订单号
      MESSAGE gs_item-vbeln TYPE 'I'.
  ENDCASE.

ENDFORM.

补充扩展知识

调用REUSE_ALV_GRID_DISPLAY_LVC函数显示ALV，在调用该函数之前，需要先定义Layout和Fieldcat，该函数对应的Layout 类型为lvc_s_layo，Fieldcat类型为lvc_s_fcat

Layout主要用于设定 ALV的输出格式

Fieldcat主要用于ALV的结构定义，包括具体的栏位及名称、类型、格式等属性

本文涉及到的相关知识点

[SAP ABAP] ALV状态栏GUI STATUS的快速创建icon-default.png?t=O83Ahttps://blog.csdn.net/Hudas/article/details/144565584?spm=1001.2014.3001.5502[SAP ABAP] ALV中的USER_COMMAN用户事件icon-default.png?t=O83Ahttps://blog.csdn.net/Hudas/article/details/144588762?spm=1001.2014.3001.5502[SAP ABAP] INCLUDE程序创建icon-default.png?t=O83Ahttps://blog.csdn.net/Hudas/article/details/142750537

[SAP ABAP] ALV基础开发icon-default.png?t=O83Ahttps://blog.csdn.net/Hudas/article/details/135887821[SAP ABAP] 选择屏幕事件icon-default.png?t=O83Ahttps://blog.csdn.net/Hudas/article/details/142894916[SAP ABAP] SELECTION-SCREENicon-default.png?t=O83Ahttps://blog.csdn.net/Hudas/article/details/142623521

本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若转载，请注明出处：/a/939355.html

如若内容造成侵权/违法违规/事实不符，请联系我们进行投诉反馈qq邮箱809451989@qq.com，一经查实，立即删除！

相关文章

Docker日志与监控

Docker日志与监控

一、引言 随着容器技术在生产环境中被广泛应用&#xff0c;Docker容器的日志管理与监控变得尤为重要。在现代应用程序中&#xff0c;容器化的应用通常是由多个容器组成的服务&#xff0c;而容器中的日志与监控则是确保服务健康运行、诊断问题和优化性能的关键。通过日志和监控…
阅读更多...
信号槽【QT】

信号槽【QT】

文章目录 对象树字符集信号槽QT坐标系信号与槽connect自定义槽自定义信号disconnect 对象树 #ifndef MYLABEL_H #define MYLABEL_H#include<QLabel> class MyLabel : public QLabel { public:// 构造函数使用带 QWidget* 版本的.// 确保对象能够加到对象树上MyLabel(QWi…
阅读更多...
3.zabbix中文设置

3.zabbix中文设置

1、zabbix中文设置 2、中文乱码的原因 zabbix使用DejaVuSan.ttf字体&#xff0c;不支持中文&#xff0c;导致中文出现乱码。解决方法很简单&#xff0c;把我们电脑里面字体文件传到zabbix服务器上。 3、解决zabbix乱码方法 3.1、从Window服务器找到相应的字休复制到zabbix S…
阅读更多...
电脑连接不上手机热点 找不到到服务器的ip地址

电脑连接不上手机热点 找不到到服务器的ip地址

手机热点连接不上 找不到到服务器的ip地址 emmm希望不会有人不会吧 解决方法&#xff1a; 1.点击右上角图标进入设置 2.点击更改所有wifi网络的DNS设置 3.查看自己的IP分配和DNS分配是不是DHCP自动分配&#xff0c;不是的话就不对了&#xff0c;需要点击编辑手动改一下 4.改完…
阅读更多...
计算机网络之王道考研读书笔记-2

计算机网络之王道考研读书笔记-2

第 2 章 物理层 2.1 通信基础 2.1.1 基本概念 1.数据、信号与码元 通信的目的是传输信息。数据是指传送信息的实体。信号则是数据的电气或电磁表现&#xff0c;是数据在传输过程中的存在形式。码元是数字通信中数字信号的计量单位&#xff0c;这个时长内的信号称为 k 进制码…
阅读更多...
MySQL数据库04|内置函数、存储过程、视图、事务、索引

MySQL数据库04|内置函数、存储过程、视图、事务、索引

目录 十三、MySQL常用内置函数 1、字符串函数 1️⃣拼接字符串&#xff1a;concat(str1,str2,…) 2️⃣包含字符个数&#xff1a;length(str) 3️⃣截取字符串&#xff1a;left(str,len)、right(str,len)、substring(str,pos,len) 4️⃣去除空格&#xff1a;ltrim(str)、r…
阅读更多...
【Unity3D】实现可视化链式结构数据（节点数据）

【Unity3D】实现可视化链式结构数据（节点数据）

关键词&#xff1a;UnityEditor、可视化节点编辑、Unity编辑器自定义窗口工具 使用Newtonsoft.Json、UnityEditor相关接口实现 主要代码&#xff1a; Handles.DrawBezier(起点&#xff0c;终点&#xff0c;起点切线向量&#xff0c;终点切线向量&#xff0c;颜色&#xff0c;n…
阅读更多...
Group FLUX - Beta Sprint Essay2

Group FLUX - Beta Sprint Essay2

文章目录 I. SCRUMAchievements from yesterday’s stand-up meeting to the present Commit recordFrontend-CommitsBackend-Commits PM ReportBurnup mapRunning image of our current program I. SCRUM Achievements from yesterday’s stand-up meeting to the present Zh…
阅读更多...
硬盘清洁器 -一个功能出色的的文件与使用纪录清理工具，不仅可以将磁盘中不必要的暂存盘一次扫除，供大家学习研究参考

硬盘清洁器 -一个功能出色的的文件与使用纪录清理工具，不仅可以将磁盘中不必要的暂存盘一次扫除，供大家学习研究参考

【核心功能】 1.硬件性能检测。 2.清理日常垃圾信息。 3.永久性删除文件。不可恢复擦除可用空间。 4.系统恢复和还原。 5.磁盘管理。 6.重复文件删除。坏链清除&#xff0c;删除非必要文件。 7.恢复删除文件。含电子照片、PDF、视频等。 8.批量重命名。 下载&#xff1a;https:…
阅读更多...
[Linux] 进程信号概念 | 信号产生

[Linux] 进程信号概念 | 信号产生

&#x1fa90;&#x1fa90;&#x1fa90;欢迎来到程序员餐厅&#x1f4ab;&#x1f4ab;&#x1f4ab; 主厨&#xff1a;邪王真眼 主厨的主页&#xff1a;Chef‘s blog 所属专栏&#xff1a;青果大战linux 总有光环在陨落&#xff0c;总有新星在闪烁 为什么我的课设这么难…
阅读更多...
流程引擎Activiti性能优化方案

流程引擎Activiti性能优化方案

流程引擎Activiti性能优化方案 Activiti工作流引擎架构概述 Activiti工作流引擎架构大致分为6层。从上到下依次为工作流引擎层、部署层、业务接口层、命令拦截层、命令层和行为层。 基于关系型数据库层面优化 MySQL建表语句优化 Activiti在MySQL中创建默认字符集为utf8&…
阅读更多...
51c视觉~合集36

51c视觉~合集36

我自己的原文哦~ https://blog.51cto.com/whaosoft/12275223 #无监督盲超分算法MLMC 即插即用的解决方案 本文介绍了一种新的无监督盲超分辨率算法MLMC&#xff0c;该算法结合了元学习和马尔可夫链蒙特卡罗核估计&#xff0c;无需监督预训练或参数先验&#xff0c;即可实现…
阅读更多...
Firecrawl教程①：自动化抓取与数据转化，赋能AI应用

Firecrawl教程①：自动化抓取与数据转化，赋能AI应用

Firecrawl教程①：自动化抓取与数据转化，赋能AI应用 前言一、功能特点1. 支持 LLM 可处理的数据格式2. 全面抓取网站3. 强大的操作支持4. 灵活的定制选项5. 支持多种编程语言 SDK二、如何开始使用 Firecrawl第一步：获取 API 密钥第二步：官网在线工具使用第三步：安装 Firecr…
阅读更多...
关于目标检测YOLO 各版本区别v1-v11/X/R/P

关于目标检测YOLO 各版本区别v1-v11/X/R/P

概述 YOLO&#xff08;You Only Look Once&#xff0c;你只看一次&#xff09;是一系列开创性的实时目标检测模型&#xff0c;它们彻底改变了计算机视觉领域。由Joseph Redmon开发&#xff0c;后续版本由不同研究人员迭代&#xff0c;YOLO模型以其在图像中检测对象的高速度和准…
阅读更多...
SpringBoot3整合FastJSON2如何配置configureMessageConverters

SpringBoot3整合FastJSON2如何配置configureMessageConverters

在 Spring Boot 3 中整合 FastJSON 2 主要涉及到以下几个步骤&#xff0c;包括添加依赖、配置 FastJSON 作为 JSON 处理器等。下面是详细的步骤&#xff1a; 1. 添加依赖 首先&#xff0c;你需要在你的 pom.xml 文件中添加 FastJSON 2 的依赖。以下是 Maven 依赖的示例&#…
阅读更多...
java全栈day19--Web后端实战(java操作数据库3)

java全栈day19--Web后端实战(java操作数据库3)

一、MyBatis 1.1介绍 前提引入&#xff1a; controller(控制层)作用&#xff1a;接受请求&#xff0c;响应数据 service(业务层)作用&#xff1a;负责具体的逻辑处理 dao(持久层)作用&#xff1a;数据访问层 一般的访问流程&#xff1a;浏览器发起请求过来&#xff0c;先…
阅读更多...
社区版 IDEA 开发webapp 配置tomcat

社区版 IDEA 开发webapp 配置tomcat

1.安装tomcat 2.构建webapp项目结构 3.配置tomcat 安装smart tomcat插件 完成后settings会多一个选项tomcat server&#xff0c;然后我们把本地的tomcat配置过去。 4.为项目配置tomcat 配置项目路径&#xff0c;端口号。Context path 配置/ 表示直接用localhost就能访问 5.添加…
阅读更多...
重新定义页签！Choerodon UI Tabs让管理更高效

重新定义页签！Choerodon UI Tabs让管理更高效

01 引言 Tabs 组件通过提供平级区域&#xff0c;将大块内容进行有效的收纳和展现&#xff0c;从而保持界面整洁。但在企业应用的快速发展中&#xff0c;这样传统的页签组件已无法满足我们对界面布局和个性化展示的追求。Choerodon UI Tabs 组件通过支持多级分组、个性化配置、…
阅读更多...
Qt编译MySQL数据库驱动

Qt编译MySQL数据库驱动

目录 Qt编译MySQL数据库驱动 测试程序 Qt编译MySQL数据库驱动 &#xff08;1&#xff09;先找到MySQL安装路径以及Qt安装路径 C:\Program Files\MySQL\MySQL Server 8.0 D:\qt\5.12.12 &#xff08;2&#xff09;在D:\qt\5.12.12\Src\qtbase\src\plugins\sqldrivers\mysql下…
阅读更多...
vulnhub靶场【DriftingBlues】之9 final

vulnhub靶场【DriftingBlues】之9 final

前言 靶机&#xff1a;DriftingBlues-6&#xff0c;IP地址192.168.1.66 攻击&#xff1a;kali&#xff0c;IP地址192.168.1.16 都采用虚拟机&#xff0c;网卡为桥接模式 主机发现 使用arp-scan -l或netdiscover -r 192.168.1.1/24 信息收集 使用nmap扫描端口 网站探测 访…
阅读更多...
最新文章

Copyright @ 2022~2023