8.4.2 延迟绑定和多态性

​ Object Pascal 函数和过程通常基于静态绑定，也称为早期绑定。这意味着方法调用是在编译或链接时解决的。面向对象编程语言允许延迟绑定或动态绑定，即根据用于调用的实例类型在运行时确定要调用的方法。

​ 这种技术的优势被称为多态性。多态性允许你编写方法调用，并将其应用到变量上。但是，Delphi 会根据变量指向的对象类型来确定实际要调用的方法。由于前面讨论过的类型兼容性规则，Delphi 在运行前无法确定变量所指对象的实际类别。

​ 与 C++ 和 C# 类似，Object Pascal 方法默认为早期绑定。这被认为更有效率。而 Java 则默认为延迟绑定（并提供了向编译器表明可以使用早期绑定优化方法的方法）。

​ 假设一个类及其子类（比方说 TAnimal 和 TDog）都定义了一个方法，并且该方法可以延迟绑定。现在你可以将此方法应用于一个通用变量，如 FMyAnimal，该变量在运行时可以引用 TAnimal 类的一个对象，也可以引用 TDog 类的一个对象。实际调用的方法将在运行时根据当前对象的类确定。

​ Animals2 示例扩展了 Animals1 项目，演示了这一技术。在新版本中，TAnimal 和 TDog 类都有一个新方法： Voice（声音），它可以输出所选动物发出的声音，既可以是文本，也可以是声音。该方法在 TAnimal 类中被定义为虚方法，随后我们在定义 TDog 类时使用virtual和override关键字覆盖该方法：

type
  TAnimal = class
  public
    function Voice: string; virtual;
  end;

  TDog = class(TAnimal)
  public
    function Voice: string; override;
  end;

当然，这两种方法也需要被实现。这是一种简单的方法：

function TAnimal.Voice: string;
begin
  Result := 'AnimalVoice';
end;

function TDog.Voice: string;
begin
  Result := 'ArfArf';
end;

​ 现在调用FMyAnimal.Voice有什么效果呢？这取决于当前对象的类型。如果FMyAnimal变量当前引用TAnimal类的对象，它将调用TAnimal.Voice方法。如果它引用TDog类的对象，它将调用TDog.Voice方法。这仅仅是因为该函数是虚函数。

​ 调用 FMyAnimal.Voice 将对 TAnimal 类的任何子类的实例对象有效，即使是在此方法调用后定义的或在其作用域之外的类。编译器不需要知道所有的子类就能使调用与它们兼容；只需要知道祖先类。换句话说，对 FMyAnimal.Voice 的调用与 TAnimal 未来的所有子类兼容。

​ 这就是为什么面向对象编程语言青睐可重用性的关键技术原因。你可以使用层次结构中的类编写代码，而不需要知道该层次结构中的具体类。换句话说，即使你已经编写了成千上万行代码，类层次结构和程序仍然是可扩展的。当然，有一个条件—层次结构中的祖先类需要精心设计。

​ Animals2 示例演示了这些新类的使用，其形式与前一示例类似。点击按钮即可执行该代码，显示输出并发出声音：

begin
  Show(FMyAnimal.Voice);
  MediaPlayer1.FileName := SoundsFolder + FMyAnimal.Voice + '.wav';
  MediaPlayer1.Play;
end;

注解：该应用程序使用MediaPlayer组件播放应用程序附带的两个声音文件（声音文件的名称与Voice方法返回的实际声音相匹配）。通用动物的一个相当随机的噪音，狗的一些吠叫声。现在，代码在Windows上很容易工作，只要文件在适当的文件夹中，但在移动平台上部署需要一些努力。查看实际演示以了解部署和文件夹结构是如何组织的。