Michael.W基于Foundry精读Openzeppelin第56期——VestingWallet.sol

Michael.W基于Foundry精读Openzeppelin第56期——VestingWallet.sol

      • 0. 版本
        • 0.1 VestingWallet.sol
      • 1. 目标合约
      • 2. 代码精读
        • 2.1 constructor()
        • 2.2 beneficiary() && start() && duration() && receive() payable
        • 2.3 released() && releasable() && vestedAmount(uint64 timestamp) && release()
        • 2.4 released(address token) && releasable(address token) && vestedAmount(address token, uint64 timestamp) && release(address token)

0. 版本

[openzeppelin]：v4.8.3，[forge-std]：v1.5.6

0.1 VestingWallet.sol

Github: https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.8.3/contracts/finance/VestingWallet.sol

VestingWallet库可以给指定的受益人地址按照时间线性释放锁在合约内的Eth和Erc20 token。任何转移至本合约的token都必须遵循释放模型。开发者可通过重写函数vestedAmount(uint64 timestamp)或vestedAmount(address token, uint64 timestamp)来自定义token释放模型。

1. 目标合约

VestingWallet合约可直接部署。

全部foundry测试合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/test/finance/VestingWallet/VestingWallet.t.sol

测试使用的物料合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/test/finance/VestingWallet/MockERC20.sol

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.0;

import "openzeppelin-contracts/contracts/token/ERC20/ERC20.sol";

contract MockERC20 is ERC20 {
    constructor(string memory name, string memory symbol)
    ERC20(name, symbol) {}

    function mint(address account, uint amount) external {
        _mint(account, amount);
    }
}

2. 代码精读

2.1 constructor()
    event EtherReleased(uint256 amount);
    event ERC20Released(address indexed token, uint256 amount);

    // 已释放的eth总量
    uint256 private _released;
    // 记录已释放的各erc20总量（key为erc20地址）
    mapping(address => uint256) private _erc20Released;
    // 受益人地址
    address private immutable _beneficiary;
    // 释放开始时间戳
    uint64 private immutable _start;
    // 释放总时长
    uint64 private immutable _duration;

    constructor(
        address beneficiaryAddress,
        uint64 startTimestamp,
        uint64 durationSeconds
    ) payable {
        // 受益人地址必须是非0地址
        require(beneficiaryAddress != address(0), "VestingWallet: beneficiary is zero address");
        // 设置受益人地址
        _beneficiary = beneficiaryAddress;
        // 设置领取开始时间戳
        _start = startTimestamp;
        // 设置释放总时长
        _duration = durationSeconds;
    }

foundry代码验证：

contract VestingWalletTest is Test {
    VestingWallet private _testing;
    address private _beneficiary = address(1024);
    uint64 private _startTimestamp = 100;
    uint64 private _durationSeconds = 1000;

    function setUp() external {
        _testing = new VestingWallet(
            _beneficiary,
            _startTimestamp,
            _durationSeconds
        );
    }

    function test_Constructor() external {
        assertEq(_testing.beneficiary(), _beneficiary);
        assertEq(_testing.start(), _startTimestamp);
        assertEq(_testing.duration(), _durationSeconds);

        // revert with zero address of beneficiary
        vm.expectRevert("VestingWallet: beneficiary is zero address");
        new VestingWallet(address(0), _startTimestamp, _durationSeconds);
    }
}
2.2 beneficiary() && start() && duration() && receive() payable
  • beneficiary()：返回受益人地址；
  • start()：返回释放开始时间戳；
  • duration()：返回释放总时长；
  • receive() payable：当合约接收到eth时执行该函数。
    function beneficiary() public view virtual returns (address) {
        return _beneficiary;
    }

    function start() public view virtual returns (uint256) {
        return _start;
    }

    function duration() public view virtual returns (uint256) {
        return _duration;
    }
    
    receive() external payable virtual {}
2.3 released() && releasable() && vestedAmount(uint64 timestamp) && release()
  • released()：返回本合约已释放给收益人的eth总量；
  • releasable()：返回当前可释放给收益人的eth数量；
  • vestedAmount(uint64 timestamp)：计算处于时间点timestamp，理论上受益人可获得的eth总量；
  • release()：释放eth给受益人。
    function released() public view virtual returns (uint256) {
        return _released;
    }
    
    function releasable() public view virtual returns (uint256) {
        // 返回值为：截止到目前，理论上应释放的eth数量 - 截止到目前，已释放给受益人的eth数量
        return vestedAmount(uint64(block.timestamp)) - released();
    }
    
    function vestedAmount(uint64 timestamp) public view virtual returns (uint256) {
        // 使用时间线性的释放模型。模型输入总量为当前该合约名下全部eth数量与已释放eth数量之和，计算的基准时间点为timestamp
        return _vestingSchedule(address(this).balance + released(), timestamp);
    }
    
    function release() public virtual {
        // 获得当前可释放给收益人的eth数量
        uint256 amount = releasable();
        // 本合约已释放给收益人的eth总量自增amount
        _released += amount;
        // 抛出事件
        emit EtherReleased(amount);
        // 使用Address库，将数量为amount的eth从本合约转给受益人
        Address.sendValue(payable(beneficiary()), amount);
    }
    
    // 释放模型，当前代码实现为时间线性模型。
    // - totalAllocation：总的应释放数量
    // - timestamp：计算的基准时间点
    function _vestingSchedule(uint256 totalAllocation, uint64 timestamp) internal view virtual returns (uint256) {
        if (timestamp < start()) {
            // 如果当前时间戳未到开始时间，返回0
            return 0;
        } else if (timestamp > start() + duration()) {
            // 如果当前时间戳超过了释放期，返回totalAllocation
            return totalAllocation;
        } else {
            // 如果当前时间戳处于释放期内，返回 totalAllocation * 从释放开始到现在流逝时间 / 总释放时长
            return (totalAllocation * (timestamp - start())) / duration();
        }
    }

foundry代码验证：

contract VestingWalletTest is Test {
    VestingWallet private _testing;
    address private _beneficiary = address(1024);
    uint64 private _startTimestamp = 100;
    uint64 private _durationSeconds = 1000;
    uint private _initialAmount = 10000;

    function setUp() external {
        _testing = new VestingWallet(
            _beneficiary,
            _startTimestamp,
            _durationSeconds
        );

        // set eth balance
        vm.deal(address(_testing), _initialAmount);
    }

    event EtherReleased(uint amount);

    function test_releaseEth() external {
        // case 1: before start time
        uint64 currentTimestamp = uint64(block.timestamp);
        assertEq(currentTimestamp, 1);
        // test released()
        assertEq(_testing.released(), 0);
        // test releasable()
        assertEq(_testing.releasable(), 0);
        // test vestedAmount(uint64 timestamp)
        assertEq(_testing.vestedAmount(currentTimestamp), 0);

        // at the start time
        vm.warp(_startTimestamp);
        assertEq(_testing.released(), 0);
        assertEq(_testing.releasable(), 0);
        assertEq(_testing.vestedAmount(_startTimestamp), 0);

        // in the duration (first release)
        currentTimestamp = _startTimestamp + 200;
        vm.warp(currentTimestamp);
        uint amountToRelease = _initialAmount * 200 / _durationSeconds;
        assertEq(_testing.released(), 0);
        assertEq(_testing.releasable(), amountToRelease);
        assertEq(_testing.vestedAmount(currentTimestamp), _initialAmount * 200 / _durationSeconds);

        // test release()
        assertEq(address(_testing).balance, _initialAmount);
        vm.expectEmit(address(_testing));
        emit EtherReleased(amountToRelease);
        _testing.release();

        assertEq(address(_testing).balance, _initialAmount - amountToRelease);
        assertEq(_beneficiary.balance, amountToRelease);
        assertEq(_testing.released(), amountToRelease);
        assertEq(_testing.releasable(), 0);
        assertEq(_testing.vestedAmount(currentTimestamp), amountToRelease);

        // in the duration (second release)
        currentTimestamp = currentTimestamp + 400;
        vm.warp(currentTimestamp);
        uint released = amountToRelease;
        amountToRelease = _initialAmount * 400 / _durationSeconds;
        assertEq(_testing.released(), released);
        assertEq(_testing.releasable(), amountToRelease);
        assertEq(_testing.vestedAmount(currentTimestamp), released + amountToRelease);

        // test release()
        assertEq(address(_testing).balance, _initialAmount - released);
        _testing.release();
        assertEq(address(_testing).balance, _initialAmount - released - amountToRelease);
        assertEq(_beneficiary.balance, released + amountToRelease);
        assertEq(_testing.released(), released + amountToRelease);
        assertEq(_testing.releasable(), 0);
        assertEq(_testing.vestedAmount(currentTimestamp), released + amountToRelease);

        // after end time
        currentTimestamp = _startTimestamp + _durationSeconds + 1;
        vm.warp(currentTimestamp);
        released += amountToRelease;
        amountToRelease = _initialAmount - released;
        assertEq(_testing.released(), released);
        assertEq(_testing.releasable(), amountToRelease);
        assertEq(_testing.vestedAmount(currentTimestamp), _initialAmount);

        // test release()
        assertEq(address(_testing).balance, _initialAmount - released);
        _testing.release();
        assertEq(address(_testing).balance, 0);
        assertEq(_beneficiary.balance, _initialAmount);
        assertEq(_testing.released(), _initialAmount);
        assertEq(_testing.releasable(), 0);
        assertEq(_testing.vestedAmount(currentTimestamp), _initialAmount);
    }
}
2.4 released(address token) && releasable(address token) && vestedAmount(address token, uint64 timestamp) && release(address token)
  • released(address token)：返回本合约已释放给受益人的erc20总量（erc20地址是token）；
  • releasable(address token)：返回当前可释放给收益人的地址为token的erc20数量；
  • vestedAmount(address token, uint64 timestamp)：计算处于时间点timestamp，理论上受益人可获得的地址为token的erc20总量；
  • release(address token)：释放地址为token的erc20给受益人。
    function released(address token) public view virtual returns (uint256) {
        return _erc20Released[token];
    }
    
    function releasable(address token) public view virtual returns (uint256) {
        // 返回值为：截止到目前，理论上应释放的地址为token的erc20数量 - 截止到目前，已释放给受益人的地址为token的erc20数量
        return vestedAmount(token, uint64(block.timestamp)) - released(token);
    }
    
    function vestedAmount(address token, uint64 timestamp) public view virtual returns (uint256) {
        // 使用时间线性的释放模型。模型输入总量为当前该合约名下地址为token的erc20数量与已释放的该token总量之和，计算的基准时间点为timestamp
        return _vestingSchedule(IERC20(token).balanceOf(address(this)) + released(token), timestamp);
    }
    
    function release(address token) public virtual {
        // 获得当前可释放给收益人的地址为token的erc20的数量
        uint256 amount = releasable(token);
        // 本合约已释放给受益人的erc20总量（erc20地址是token）自增amount
        _erc20Released[token] += amount;
        // 抛出事件
        emit ERC20Released(token, amount);
        // 使用SafeERC20库，将数量为amount的地址为token的erc20转给受益人
        SafeERC20.safeTransfer(IERC20(token), beneficiary(), amount);
    }

foundry代码验证：

contract VestingWalletTest is Test {
    VestingWallet private _testing;
    MockERC20 private _erc20 = new MockERC20("test name", "test symbol");
    address private _beneficiary = address(1024);
    uint64 private _startTimestamp = 100;
    uint64 private _durationSeconds = 1000;
    uint private _initialAmount = 10000;

    function setUp() external {
        _testing = new VestingWallet(
            _beneficiary,
            _startTimestamp,
            _durationSeconds
        );

        // set erc20 balance
        _erc20.mint(address(_testing), _initialAmount);
    }

    event ERC20Released(address indexed token, uint amount);

    function test_releaseErc20() external {
        address erc20Address = address(_erc20);
        // case 1: before start time
        uint64 currentTimestamp = uint64(block.timestamp);
        assertEq(currentTimestamp, 1);
        // test released(address token)
        assertEq(_testing.released(erc20Address), 0);
        // test releasable(address token)
        assertEq(_testing.releasable(erc20Address), 0);
        // test vestedAmount(address token, uint64 timestamp)
        assertEq(_testing.vestedAmount(erc20Address, currentTimestamp), 0);

        // at the start time
        vm.warp(_startTimestamp);
        assertEq(_testing.released(erc20Address), 0);
        assertEq(_testing.releasable(erc20Address), 0);
        assertEq(_testing.vestedAmount(erc20Address, _startTimestamp), 0);

        // in the duration (first release)
        currentTimestamp = _startTimestamp + 200;
        vm.warp(currentTimestamp);
        uint amountToRelease = _initialAmount * 200 / _durationSeconds;
        assertEq(_testing.released(erc20Address), 0);
        assertEq(_testing.releasable(erc20Address), amountToRelease);
        assertEq(_testing.vestedAmount(erc20Address, currentTimestamp), _initialAmount * 200 / _durationSeconds);

        // test release(address token)
        assertEq(_erc20.balanceOf(address(_testing)), _initialAmount);
        vm.expectEmit(address(_testing));
        emit ERC20Released(erc20Address, amountToRelease);
        _testing.release(erc20Address);

        assertEq(_erc20.balanceOf(address(_testing)), _initialAmount - amountToRelease);
        assertEq(_erc20.balanceOf(_beneficiary), amountToRelease);
        assertEq(_testing.released(erc20Address), amountToRelease);
        assertEq(_testing.releasable(erc20Address), 0);
        assertEq(_testing.vestedAmount(erc20Address, currentTimestamp), amountToRelease);

        // in the duration (second release)
        currentTimestamp = currentTimestamp + 400;
        vm.warp(currentTimestamp);
        uint released = amountToRelease;
        amountToRelease = _initialAmount * 400 / _durationSeconds;
        assertEq(_testing.released(erc20Address), released);
        assertEq(_testing.releasable(erc20Address), amountToRelease);
        assertEq(_testing.vestedAmount(erc20Address, currentTimestamp), released + amountToRelease);

        // test release(address token)
        assertEq(_erc20.balanceOf(address(_testing)), _initialAmount - released);
        _testing.release(erc20Address);
        assertEq(_erc20.balanceOf(address(_testing)), _initialAmount - released - amountToRelease);
        assertEq(_erc20.balanceOf(_beneficiary), released + amountToRelease);
        assertEq(_testing.released(erc20Address), released + amountToRelease);
        assertEq(_testing.releasable(erc20Address), 0);
        assertEq(_testing.vestedAmount(erc20Address, currentTimestamp), released + amountToRelease);

        // after end time
        currentTimestamp = _startTimestamp + _durationSeconds + 1;
        vm.warp(currentTimestamp);
        released += amountToRelease;
        amountToRelease = _initialAmount - released;
        assertEq(_testing.released(erc20Address), released);
        assertEq(_testing.releasable(erc20Address), amountToRelease);
        assertEq(_testing.vestedAmount(erc20Address, currentTimestamp), _initialAmount);

        // test release(address token)
        assertEq(_erc20.balanceOf(address(_testing)), _initialAmount - released);
        _testing.release(erc20Address);
        assertEq(_erc20.balanceOf(address(_testing)), 0);
        assertEq(_erc20.balanceOf(_beneficiary), _initialAmount);
        assertEq(_testing.released(erc20Address), _initialAmount);
        assertEq(_testing.releasable(erc20Address), 0);
        assertEq(_testing.vestedAmount(erc20Address, currentTimestamp), _initialAmount);
    }
}

ps:
本人热爱图灵，热爱中本聪，热爱V神。
以下是我个人的公众号，如果有技术问题可以关注我的公众号来跟我交流。
同时我也会在这个公众号上每周更新我的原创文章，喜欢的小伙伴或者老伙计可以支持一下！
如果需要转发，麻烦注明作者。十分感谢！

在这里插入图片描述

公众号名称：后现代泼痞浪漫主义奠基人

本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若转载，请注明出处：/a/679149.html

如若内容造成侵权/违法违规/事实不符，请联系我们进行投诉反馈qq邮箱809451989@qq.com，一经查实，立即删除！

相关文章

加密经济浪潮：探索Web3对金融体系的颠覆

加密经济浪潮：探索Web3对金融体系的颠覆

随着区块链技术的快速发展&#xff0c;加密经济正在成为全球金融领域的一股新的浪潮。而Web3作为下一代互联网的代表&#xff0c;以其去中心化、可编程的特性&#xff0c;正深刻影响着传统金融体系的格局和运作方式。本文将深入探讨加密经济对金融体系的颠覆&#xff0c;探索We…
阅读更多...
普通人下班可以做点什么补偿家用

普通人下班可以做点什么补偿家用

你我&#xff0c;或者说大多数的都是普通人&#xff0c;每个人都在为了生活奔波&#xff0c;没有惊天动地的才华&#xff0c;也没有一夜暴富的运气&#xff0c;但我们依然可以通过自己的双手和智慧&#xff0c;为家庭添上一份温馨。白天的工作往往只能满足基本的生活需求&#…
阅读更多...
IIS7整合Tomcat9服务器，并搭建ASP+PHP+JSP完整运行环境

IIS7整合Tomcat9服务器，并搭建ASP+PHP+JSP完整运行环境

本文以Windows Vista系统为例&#xff0c;详细讲解IIS7整合Tomcat服务器&#xff0c;同时支持ASPPHPJSP三种Web动态网页技术的方法。 Vista系统自带的IIS版本为7.0&#xff0c;能安装的IE浏览器的最高版本为IE9。IE9也是Vue2前端框架支持的最低浏览器版本。 【准备工作】 去微…
阅读更多...
第六讲:AD、DA的工作原理及实现、运放电路

第六讲:AD、DA的工作原理及实现、运放电路

DA 数模转换器 (DAC) 数模转换器&#xff08;Digital-to-Analog Converter&#xff0c;简称DAC&#xff09;是一种将数字信号转换为模拟信号的电子装置。DAC在各种电子设备中广泛应用&#xff0c;如音频设备、通信系统、测量设备和控制系统中。以下是DAC的主要概念和应用。…
阅读更多...
已发【镜像仿真篇】ESXi镜像仿真教程

已发【镜像仿真篇】ESXi镜像仿真教程

【镜像仿真篇】ESXi镜像仿真教程 我以为不会再有使用FTK Imager低版本的时候&#xff0c;毕竟Arsenal Image Mounte是我目前遇到的最强镜像挂载软件&#xff0c;直到这次遇到了这个ESXi镜像仿真的时候一直报错—【蘇小沐】 1、实验环境 FTK Imanger &#xff0c;[v3.1.1.8]V…
阅读更多...
李廉洋：6.4-6.5黄金原油再次走低，美盘行情分析及最新策略。

李廉洋：6.4-6.5黄金原油再次走低，美盘行情分析及最新策略。

黄金消息面分析&#xff1a;全球债券周二上涨&#xff0c;呼应美债隔夜的涨势。美联储或早降息的押注增强了主权债务的吸引力。澳大利亚和新西兰10年期债券收益率下跌至少8个基点&#xff0c;先前数据显示&#xff0c;美国5月份工厂活动萎缩的速度加快。日本10年期债券收益率下…
阅读更多...
01_深度学习基础知识

01_深度学习基础知识

1. 感知机 感知机通常情况下指单层的人工神经网络，其结构与 MP 模型类似（按照生物神经元的结构和工作原理造出来的一个抽象和简化了模型，也称为神经网络的一个处理单元） 假设由一个 n 维的单层感知机，则： x 1 x_1 x1​ 至 x n x_n xn​ 为 n 维输入向量的各个分量w 1 j…
阅读更多...
云原生架构案例分析_4.某电商业务云原生改造

云原生架构案例分析_4.某电商业务云原生改造

名称解释&#xff1a; AHAS&#xff1a;应用高可用服务&#xff08;Application High Availability Service&#xff09;是一款专注于提高应用高可用能力的SaaS产品&#xff0c;主要包含多活容灾、故障演练和流量防护三个独立的功能模块。其中流量防护已迁移至微服务治理服务MS…
阅读更多...
windows hash简介

windows hash简介

一、hash简介 1、Windows系统使用两种方法对用户的密码进行哈希处理。它们分别是LAN Manager(LM)哈希和 NT LAN Manager(NTLM)哈希 2、所谓哈希(hash)&#xff0c;就是使用一种加密函数进行计算后的结果。这个加密函数对一个任意长度的 字符串数据进行一次数学加密函数运算…
阅读更多...
计网ppt标黄知识点整理第（4）章节——谢希仁版本、期末复习自用

计网ppt标黄知识点整理第（4）章节——谢希仁版本、期末复习自用

路由器&#xff1a;查找转发表&#xff0c;转发分组。 IP网的意义&#xff1a;当互联网上的主机进行通信时&#xff0c;就好像在一个网络上通信一样&#xff0c;看不见互连的各具体的网络异构细节。如果在这种覆盖全球的 IP 网的上层使用 TCP 协议&#xff0c;那么就…
阅读更多...
Spring运维之boot项目开发关键之日志操作以及用文件记录日志

Spring运维之boot项目开发关键之日志操作以及用文件记录日志

日志基础 日志 在企业级开发中还是比较重要的 我们来写一个日志 RestController RequestMapping("/books") public class Controller {//创建记录日志的对象private static final Logger log LoggerFactory.getLogger(Controller.class);GetMappingpublic String …
阅读更多...
开源基于Rust编写的Web服务器

开源基于Rust编写的Web服务器

基于 RUST 的 WEB 资源服务器 Github 地址 LTPP-GIT 地址 官方文档 该项目于 2024 年 5 月 1 日开始开发 预期功能 功能支持情况当前情况多线程支持是是服务支持配置化是是防盗链支持是是gzip 支持是是反向代理支持是是自定义状态码对应资源文件是是日志支持是是负载均衡支…
阅读更多...
【Python绘画】画笑脸简笔画

【Python绘画】画笑脸简笔画

本文收录于 《一起学Python趣味编程》专栏&#xff0c;从零基础开始&#xff0c;分享一些Python编程知识&#xff0c;欢迎关注&#xff0c;谢谢&#xff01; 文章目录 一、前言二、代码示例三、知识点梳理四、总结 一、前言 本文介绍如何使用Python的海龟画图工具turtle&#…
阅读更多...
BUUCTF [XMAN2018排位赛]通行证 1

BUUCTF [XMAN2018排位赛]通行证 1

BUUCTF:https://buuoj.cn/challenges 题目描述&#xff1a; 得到的 flag 请包上 flag{} 提交。来源&#xff1a;https://github.com/hebtuerror404/CTF_competition_warehouse_2018 密文&#xff1a; a2FuYmJyZ2doamx7emJfX19ffXZ0bGFsbg解题思路&#xff1a; 1、两个等号…
阅读更多...
CentOS-内网搭建FTP-Server

CentOS-内网搭建FTP-Server

一、镜像选择 1、 Centos-everting或者DVD 2、7.5 7.6 7.9 均可 二、安装步骤 1、其余步骤和普通安装一致。 2、最重要的一步为“软件选择” 1、勾选FTP、文件以及存储服务器、性能以及开发工具。 三、FTPServer搭建 1、关闭防火墙 systemctl stop firewalld or 通过21和20…
阅读更多...
C/C++ 进阶（5）二叉平衡搜索树（AVL树）

C/C++ 进阶（5）二叉平衡搜索树（AVL树）

个人主页&#xff1a;仍有未知等待探索-CSDN博客 专题分栏&#xff1a;C 目录 一、概念 二、平衡因子 三、操作 插入 旋转 左单旋 右单旋 左右双旋 右左双旋 一、概念 二叉平衡搜索树又称AVL树&#xff0c;是一种特殊的二叉搜索树。一般的二叉搜索树在遇到数据有序时&…
阅读更多...
【MySQL】sql语句之库操作

【MySQL】sql语句之库操作

序言 在上篇文章学习当中&#xff0c;我们认识了数据库的相关概念&#xff0c;以及MySQL的框架和基本使用等内容&#xff0c;总之对数据库有了一个大致的认识&#xff0c;那么本篇文章将开始关于sql语句的学习&#xff0c;本文主要是关于库的属性和操作的内容&#xff0c;简单可…
阅读更多...
2024网络与信息安全管理员职工职业技能竞赛re0220164094

2024网络与信息安全管理员职工职业技能竞赛re0220164094

main部分&#xff0c;就是要逆这部分shellcode&#xff0c;程序把data段里面的东西复制到bss段去执行&#xff0c;期间包含解码操作。 v19 0;puts("Please input your flag: ");__isoc99_scanf("%s", s);if ( strlen(s) ! 38 ){puts("Wrong length!&…
阅读更多...
yolov5模型结构与构建原理

yolov5模型结构与构建原理

一.yolov5模型结构与构建原理 修改模型结构&#xff0c;全部在models文件夹下面 models/common.py &#xff08;加入新增网络细节&#xff09; models/yolo.py &#xff08;设定网络结构传参细节&#xff09; models/##.yaml &#xff08;修改模型结构配置文…
阅读更多...
数字信号处理实验四：IIR数字滤波器设计及软件实现

数字信号处理实验四：IIR数字滤波器设计及软件实现

一、实验目的 1. 掌握MATLAB中进行IIR模拟滤波器的设计的相关函数的应用&#xff1b; 2. 掌握MATLAB的工具箱中提供的常用IIR数字滤波器的设计函数的应用&#xff1b; 3.掌握MATLAB的工具箱中提供的模拟滤波器转数字滤波器的相关的设计函数的应用。 二、实验内容 本实验为…
阅读更多...
最新文章

Copyright @ 2022~2023