STM32启动过程分析

Keil堆栈设置注意事项

一、启动模式

复位方式：上电复位、硬件复位、软件复位

从地址0x0000 0000处取出堆栈指针MSP的初始值，该值就是栈顶地址。
从地址0x0000 0004处取出程序计数器指针PC的初始值，该值指向复位后执行的第一条指令。

说白了就是从0x0000 0000的映射地址取MSP，从0x0000 0004的映射地址取PC。

SRAM启动模式需要用启动文件startup_stm32f103xe.s这个文件决定是FLASH还是SRAM。

系统存储器是存放ST公司的固化代码的，用不了。

二、启动文件分析

startup_stm32f103xe.s由汇编编写

2.1启动文件的工作

初始化堆栈指针 SP = _initial_sp
初始化程序计数器指针 PC = Reset_Handler
设置堆和栈的大小
初始化中断向量表
配置外部SRAM作为数据存储器（可选）
配置系统时钟，通过调用SystemInit函数（可选）
调用C库中的_main函数初始化用户堆栈，最终调用main函数

keil界面->Help->uVision Help可以查询汇编指令。

2.2启动文件代码分析

2.2.1栈分配：

Stack_Size      EQU     0x00000400

                AREA    STACK, NOINIT, READWRITE, ALIGN=3
Stack_Mem       SPACE   Stack_Size
__initial_sp

源码含义：

开辟一段大小为 0x0000 0400 （ 1KB ）的栈空间。

AREA 汇编一个新的代码段或者数据段。段名为 STACK ， NOINIT 表示

不初始化； READWRITE 表示可读可写； ALIGN =3 ，表示按照 2^3 对齐，即 8 字节对齐。

SPACE 分配内存指令，分配大小为 Stack_Size 字节连续的存储单元给栈空间。

__initial_sp 紧挨着 SPACE 放置，表示栈的结束地址， 栈是从高往低生长，所以结束地址就

是栈顶地址。

栈主要用于存放局部变量，函数形参等，属于编译器自动分配和释放的内存，栈的大小不能超过内部 SRAM 的大小。如果工程的程序量比较大，定义的局部变量比较多，那么就需要在启动代码中修改栈的大小，即修改 Stack_Size 的值。如果程序出现了莫名其妙的错误，并进入了 HardFault 的时候，你就要考虑下是不是栈空间不够大，溢出了的问题。

2.2.2堆分配：

Heap_Size       EQU     0x00000200

                AREA    HEAP, NOINIT, READWRITE, ALIGN=3
__heap_base
Heap_Mem        SPACE   Heap_Size
__heap_limit

                PRESERVE8
                THUMB

源码含义：

开辟一段大小为 0x0000 0200 （ 512 字节）的堆空间，段名为 HEAP ，不初始化，可读可写，8 字节对齐。

__heap_base 表示堆的起始地址， __heap_limit 表示堆的结束地址。堆和栈的生长方向相反

的， 堆是由低向高生长，而栈是从高往低生长。

堆主要用于动态内存的分配，像 malloc() 、calloc()和 realloc() 等函数申请的内存就在堆上

面。堆中的内存一般由程序员分配和释放，若程序员不释放，程序结束时可能由操作系统回

收。

PRESERVE8 ：指示编译器按照 8 字节对齐。

THUMB ：指示编译器之后的指令为 THUMB 指令。

2.2.3中断向量表定义：

                AREA    RESET, DATA, READONLY
                EXPORT  __Vectors
                EXPORT  __Vectors_End
                EXPORT  __Vectors_Size

源码含义：

定义一个数据段，名字为 RESET，READONLY 表示只读。

EXPORT 表示声明一个标号具有全局属性，可被外部的文件使用。这里是声明__Vectors 、 __Vectors_End 和 __Vectors_Size 三个标号具有全局性，可被外部的文件使用。

__Vectors       DCD     __initial_sp               ; Top of Stack
                DCD     Reset_Handler              ; Reset Handler
                DCD     NMI_Handler                ; NMI Handler
                DCD     HardFault_Handler          ; Hard Fault Handler
                DCD     MemManage_Handler          ; MPU Fault Handler
                DCD     BusFault_Handler           ; Bus Fault Handler
                DCD     UsageFault_Handler         ; Usage Fault Handler
                DCD     0                          ; Reserved
                DCD     0                          ; Reserved
                DCD     0                          ; Reserved
                DCD     0                          ; Reserved
                DCD     SVC_Handler                ; SVCall Handler
                DCD     DebugMon_Handler           ; Debug Monitor Handler
                DCD     0                          ; Reserved
                DCD     PendSV_Handler             ; PendSV Handler
                DCD     SysTick_Handler            ; SysTick Handler

                ; External Interrupts
                DCD     WWDG_IRQHandler            ; Window Watchdog
                DCD     PVD_IRQHandler             ; PVD through EXTI Line detect
                DCD     TAMPER_IRQHandler          ; Tamper
                DCD     RTC_IRQHandler             ; RTC
                DCD     FLASH_IRQHandler           ; Flash
                DCD     RCC_IRQHandler             ; RCC
                DCD     EXTI0_IRQHandler           ; EXTI Line 0
                DCD     EXTI1_IRQHandler           ; EXTI Line 1
                DCD     EXTI2_IRQHandler           ; EXTI Line 2
                DCD     EXTI3_IRQHandler           ; EXTI Line 3
                DCD     EXTI4_IRQHandler           ; EXTI Line 4
                DCD     DMA1_Channel1_IRQHandler   ; DMA1 Channel 1
                DCD     DMA1_Channel2_IRQHandler   ; DMA1 Channel 2
                DCD     DMA1_Channel3_IRQHandler   ; DMA1 Channel 3
                DCD     DMA1_Channel4_IRQHandler   ; DMA1 Channel 4
                DCD     DMA1_Channel5_IRQHandler   ; DMA1 Channel 5
                DCD     DMA1_Channel6_IRQHandler   ; DMA1 Channel 6
                DCD     DMA1_Channel7_IRQHandler   ; DMA1 Channel 7
                DCD     ADC1_2_IRQHandler          ; ADC1 & ADC2
                DCD     USB_HP_CAN1_TX_IRQHandler  ; USB High Priority or CAN1 TX
                DCD     USB_LP_CAN1_RX0_IRQHandler ; USB Low  Priority or CAN1 RX0
                DCD     CAN1_RX1_IRQHandler        ; CAN1 RX1
                DCD     CAN1_SCE_IRQHandler        ; CAN1 SCE
                DCD     EXTI9_5_IRQHandler         ; EXTI Line 9..5
                DCD     TIM1_BRK_IRQHandler        ; TIM1 Break
                DCD     TIM1_UP_IRQHandler         ; TIM1 Update
                DCD     TIM1_TRG_COM_IRQHandler    ; TIM1 Trigger and Commutation
                DCD     TIM1_CC_IRQHandler         ; TIM1 Capture Compare
                DCD     TIM2_IRQHandler            ; TIM2
                DCD     TIM3_IRQHandler            ; TIM3
                DCD     TIM4_IRQHandler            ; TIM4
                DCD     I2C1_EV_IRQHandler         ; I2C1 Event
                DCD     I2C1_ER_IRQHandler         ; I2C1 Error
                DCD     I2C2_EV_IRQHandler         ; I2C2 Event
                DCD     I2C2_ER_IRQHandler         ; I2C2 Error
                DCD     SPI1_IRQHandler            ; SPI1
                DCD     SPI2_IRQHandler            ; SPI2
                DCD     USART1_IRQHandler          ; USART1
                DCD     USART2_IRQHandler          ; USART2
                DCD     USART3_IRQHandler          ; USART3
                DCD     EXTI15_10_IRQHandler       ; EXTI Line 15..10
                DCD     RTC_Alarm_IRQHandler        ; RTC Alarm through EXTI Line
                DCD     USBWakeUp_IRQHandler       ; USB Wakeup from suspend
                DCD     TIM8_BRK_IRQHandler        ; TIM8 Break
                DCD     TIM8_UP_IRQHandler         ; TIM8 Update
                DCD     TIM8_TRG_COM_IRQHandler    ; TIM8 Trigger and Commutation
                DCD     TIM8_CC_IRQHandler         ; TIM8 Capture Compare
                DCD     ADC3_IRQHandler            ; ADC3
                DCD     FSMC_IRQHandler            ; FSMC
                DCD     SDIO_IRQHandler            ; SDIO
                DCD     TIM5_IRQHandler            ; TIM5
                DCD     SPI3_IRQHandler            ; SPI3
                DCD     UART4_IRQHandler           ; UART4
                DCD     UART5_IRQHandler           ; UART5
                DCD     TIM6_IRQHandler            ; TIM6
                DCD     TIM7_IRQHandler            ; TIM7
                DCD     DMA2_Channel1_IRQHandler   ; DMA2 Channel1
                DCD     DMA2_Channel2_IRQHandler   ; DMA2 Channel2
                DCD     DMA2_Channel3_IRQHandler   ; DMA2 Channel3
                DCD     DMA2_Channel4_5_IRQHandler ; DMA2 Channel4 & Channel5
__Vectors_End

__Vectors 为向量表起始地址，__Vectors_End 为向量表结束地址，__Vectors_Size 为向量表大小，__Vectors_Size = __Vectors_End - __Vectors。

DCD ：分配一个或者多个以字为单位的内存，以四字节对齐，并要求初始化这些内存。中断向量表被放置在代码段的最前面。

程序在FLASH运行时，向量表起始地址为0x8000 0000，存放栈顶地址。0x8000 0004存放Reset_Handler中断函数入口地址。向量表存的就是中断服务函数的函数名，也就是地址。

2.2.4复位程序：

                AREA    |.text|, CODE, READONLY

定义一个段命为 .text ，只读的代码段，在 CODE 区。

Reset_Handler   PROC
                EXPORT  Reset_Handler             [WEAK]
                IMPORT  __main
                IMPORT  SystemInit
                LDR     R0, =SystemInit
                BLX     R0               
                LDR     R0, =__main
                BX      R0
                ENDP

PROC 、 ENDP 定义子程序，把程序段分为若干个过程，使程序的结构加清晰。

复位子程序是复位后第一个被执行的程序，主要是调用 SystemInit 函数配置系统时钟、还有就

是初始化 FSMC 总线上外挂的 SRAM( 可选 ) 。然后在调用 C 库函数 __main ，最终调用 main 函

数去到 C 的世界。

EXPORT 声明复位中断向量 Reset_Handler 为全局属性，这样外部文件就可以调用此复位

中断服务。

WEAK：表示弱定义，如果外部文件优先定义了该标号则首先引用外部定义的标号，如果

外部文件没有声明也不会出错。这里表示复位子程序可以由用户在其他文件重新实现，这里并

不是唯一的。

IMPORT 表示该标号来自外部文件。这里表示 SystemInit 和 __main 这两个函数均来自外

部的文件。

LDR 表示从存储器中加载字到一个存储器中。

BLX 表示跳转到由寄存器给出的地址，并根据寄存器的 LSE 确定处理器的状态，还要把

跳转前的下条指令地址保存到 LR 。

BX 表示跳转到由寄存器 / 标号给出的地址，不用返回。这里表示切换到 __main 地址，最

终调用 main 函数，不返回，进入 C 的世界。

2.2.5中断服务函数：

NMI_Handler     PROC
                EXPORT  NMI_Handler                [WEAK]
                B       .
                ENDP
HardFault_Handler\
                PROC
                EXPORT  HardFault_Handler          [WEAK]
                B       .
                ENDP


……


Default_Handler PROC

                EXPORT  WWDG_IRQHandler            [WEAK]
                EXPORT  PVD_IRQHandler             [WEAK]
                EXPORT  TAMPER_IRQHandler          [WEAK]
                EXPORT  RTC_IRQHandler             [WEAK]
                EXPORT  FLASH_IRQHandler           [WEAK]
                EXPORT  RCC_IRQHandler             [WEAK]
                EXPORT  EXTI0_IRQHandler           [WEAK]
                EXPORT  EXTI1_IRQHandler           [WEAK]
                EXPORT  EXTI2_IRQHandler           [WEAK]
                EXPORT  EXTI3_IRQHandler           [WEAK]
                EXPORT  EXTI4_IRQHandler           [WEAK]
                EXPORT  DMA1_Channel1_IRQHandler   [WEAK]
                EXPORT  DMA1_Channel2_IRQHandler   [WEAK]
                EXPORT  DMA1_Channel3_IRQHandler   [WEAK]
                EXPORT  DMA1_Channel4_IRQHandler   [WEAK]
                EXPORT  DMA1_Channel5_IRQHandler   [WEAK]
                EXPORT  DMA1_Channel6_IRQHandler   [WEAK]
                EXPORT  DMA1_Channel7_IRQHandler   [WEAK]
                EXPORT  ADC1_2_IRQHandler          [WEAK]
                EXPORT  USB_HP_CAN1_TX_IRQHandler  [WEAK]
                EXPORT  USB_LP_CAN1_RX0_IRQHandler [WEAK]
                EXPORT  CAN1_RX1_IRQHandler        [WEAK]
                EXPORT  CAN1_SCE_IRQHandler        [WEAK]
                EXPORT  EXTI9_5_IRQHandler         [WEAK]
                EXPORT  TIM1_BRK_IRQHandler        [WEAK]
                EXPORT  TIM1_UP_IRQHandler         [WEAK]
                EXPORT  TIM1_TRG_COM_IRQHandler    [WEAK]
                EXPORT  TIM1_CC_IRQHandler         [WEAK]
                EXPORT  TIM2_IRQHandler            [WEAK]
                EXPORT  TIM3_IRQHandler            [WEAK]
                EXPORT  TIM4_IRQHandler            [WEAK]
                EXPORT  I2C1_EV_IRQHandler         [WEAK]
                EXPORT  I2C1_ER_IRQHandler         [WEAK]
                EXPORT  I2C2_EV_IRQHandler         [WEAK]
                EXPORT  I2C2_ER_IRQHandler         [WEAK]
                EXPORT  SPI1_IRQHandler            [WEAK]
                EXPORT  SPI2_IRQHandler            [WEAK]
                EXPORT  USART1_IRQHandler          [WEAK]
                EXPORT  USART2_IRQHandler          [WEAK]
                EXPORT  USART3_IRQHandler          [WEAK]
                EXPORT  EXTI15_10_IRQHandler       [WEAK]
                EXPORT  RTC_Alarm_IRQHandler        [WEAK]
                EXPORT  USBWakeUp_IRQHandler       [WEAK]
                EXPORT  TIM8_BRK_IRQHandler        [WEAK]
                EXPORT  TIM8_UP_IRQHandler         [WEAK]
                EXPORT  TIM8_TRG_COM_IRQHandler    [WEAK]
                EXPORT  TIM8_CC_IRQHandler         [WEAK]
                EXPORT  ADC3_IRQHandler            [WEAK]
                EXPORT  FSMC_IRQHandler            [WEAK]
                EXPORT  SDIO_IRQHandler            [WEAK]
                EXPORT  TIM5_IRQHandler            [WEAK]
                EXPORT  SPI3_IRQHandler            [WEAK]
                EXPORT  UART4_IRQHandler           [WEAK]
                EXPORT  UART5_IRQHandler           [WEAK]
                EXPORT  TIM6_IRQHandler            [WEAK]
                EXPORT  TIM7_IRQHandler            [WEAK]
                EXPORT  DMA2_Channel1_IRQHandler   [WEAK]
                EXPORT  DMA2_Channel2_IRQHandler   [WEAK]
                EXPORT  DMA2_Channel3_IRQHandler   [WEAK]
                EXPORT  DMA2_Channel4_5_IRQHandler [WEAK]

WWDG_IRQHandler
PVD_IRQHandler
TAMPER_IRQHandler
RTC_IRQHandler
FLASH_IRQHandler
RCC_IRQHandler
EXTI0_IRQHandler
EXTI1_IRQHandler
EXTI2_IRQHandler
EXTI3_IRQHandler
EXTI4_IRQHandler
DMA1_Channel1_IRQHandler
DMA1_Channel2_IRQHandler
DMA1_Channel3_IRQHandler
DMA1_Channel4_IRQHandler
DMA1_Channel5_IRQHandler
DMA1_Channel6_IRQHandler
DMA1_Channel7_IRQHandler
ADC1_2_IRQHandler
USB_HP_CAN1_TX_IRQHandler
USB_LP_CAN1_RX0_IRQHandler
CAN1_RX1_IRQHandler
CAN1_SCE_IRQHandler
EXTI9_5_IRQHandler
TIM1_BRK_IRQHandler
TIM1_UP_IRQHandler
TIM1_TRG_COM_IRQHandler
TIM1_CC_IRQHandler
TIM2_IRQHandler
TIM3_IRQHandler
TIM4_IRQHandler
I2C1_EV_IRQHandler
I2C1_ER_IRQHandler
I2C2_EV_IRQHandler
I2C2_ER_IRQHandler
SPI1_IRQHandler
SPI2_IRQHandler
USART1_IRQHandler
USART2_IRQHandler
USART3_IRQHandler
EXTI15_10_IRQHandler
RTC_Alarm_IRQHandler
USBWakeUp_IRQHandler
TIM8_BRK_IRQHandler
TIM8_UP_IRQHandler
TIM8_TRG_COM_IRQHandler
TIM8_CC_IRQHandler
ADC3_IRQHandler
FSMC_IRQHandler
SDIO_IRQHandler
TIM5_IRQHandler
SPI3_IRQHandler
UART4_IRQHandler
UART5_IRQHandler
TIM6_IRQHandler
TIM7_IRQHandler
DMA2_Channel1_IRQHandler
DMA2_Channel2_IRQHandler
DMA2_Channel3_IRQHandler
DMA2_Channel4_5_IRQHandler
                B       .

                ENDP

                ALIGN

这些中断函数分为系统异常中断(内核)和外部中断(外设)，外部中断根据不同芯片有所变化。B 指令是

跳转到一个标号，这里跳转到一个‘ . ’，表示无限循环。

在启动文件代码中，已经把我们所有中断的中断服务函数写好了，但都是声明为弱定义，

所以真正的中断服务函数需要我们在外部实现。就是在外边写一个一模一样名称的函数作为中断服务函数。

如果我们开启了某个中断，但是忘记写对应的中断服务程序函数又或者把中断服务函数名

写错，那么中断发生时，程序就会跳转到启动文件预先写好的弱定义的中断服务程序中，并且

在 B 指令作用下跳转到一个‘ . ’中，无限循环。

2.2.6用户堆栈初始化

                 ALIGN

ALIGN 表示对指令或者数据的存放地址进行对齐，一般需要跟一个立即数，缺省表示 4 字
节对齐。要注意的是，这个不是 ARM 的指令，是编译器的。

;*******************************************************************************
; User Stack and Heap initialization
;*******************************************************************************
                 IF      :DEF:__MICROLIB
                
                 EXPORT  __initial_sp
                 EXPORT  __heap_base
                 EXPORT  __heap_limit
                
                 ELSE
                
                 IMPORT  __use_two_region_memory
                 EXPORT  __user_initial_stackheap
                 
__user_initial_stackheap

                 LDR     R0, =  Heap_Mem
                 LDR     R1, =(Stack_Mem + Stack_Size)
                 LDR     R2, = (Heap_Mem +  Heap_Size)
                 LDR     R3, = Stack_Mem
                 BX      LR

                 ALIGN

                 ENDIF

                 END

代码含义：

判断是否定义了__MICROLIB。

如果定义__MICROLIB，声明__initial_sp(栈顶地址)、__heap_base(堆起始地址) 和__heap_limit(堆结束地址) 这三个标号具有全局属性，可被外部的文件使用。

如果没有定义__MICROLIB ，实际的情况就是我们没有定义 __MICROLIB ，所以使用默认

的 C 库运行。那么堆栈的初始化由 C 库函数 __main 来完成。

MicroLIB 是 MDK 自带微小的库，是缺省 C 库的备选库， MicroLIB 进行了高度优化使得其
代码变得很小，功能比缺省 C 库少。 MicroLIB 是没有源码的，只有库。

2.3系统启动流程分析

以STM32F103开发板HAL库例程实验1跑马灯实验为例观察内存空间存储情况。

0x0800 0000地址存放的值是0x20000788，0x0800 0004地址存放的值是0x0800 01CD。CM3小端模式。堆栈指针SP=0x2000 0788，PC=0x0800 01CD（Reset_Handler入口地址）。

请注意，这与传统的ARM架构不同——其实也和绝大多数的其它单片机不同。

传统的ARM架构总是从 0 地址开始执行第一条指令。它们的 0 地址处总是一条跳转指令。

CM3 内核中， 0 地址处提供 MSP 的初始值，然后就是向量表（向量表在以后还可以被移至其它位置）。向量表中的数值是 32 位的地址，而不是跳转指令。向量表的第一个条目指向复位后应执行的第一条指令，就是 Reset_Handler 这个函数。

三、map文件分析

output生成.axf、.crf、.d、.dep、.hex、.lnp、.lst、.o、.htm、bulild_log.htm 和.map。

.map文件是编译器链接时生成的一个文件，主要包含 交叉链接信息，通过这个文件可以知道整个工程的 函数调用关系、FLASH和RAM占用情况及其详细汇总信息，具体到单个源文件（.c/.s）的占用情况。包含5个组成部分：

程序段交叉引用关系
删除映像未使用的程序段
映像符号表
映像内存分布图
映像组件大小

keil中map配置：

keil中打开.map文件的步骤：

确保工程编译成功（无错误）
双击LED，打开.map文件
map文件打开成功

map文件的基础概念：

Section：描述映像文件的代码或数据块，我们简称程序段
RO：Read Only 的缩写，包括只读数据（RO data）和代码（RO code）两部分内容，占用 FLASH 空间。
RW：Read Write 的缩写，包含可读写数据（RW data，有初值，且不为 0），占用 FLASH（存储初值）和 RAM（读写操作）。
ZI：Zero initialized 的缩写，包含初始化为 0 的数据（ZI data），占用 RAM 空间。
.text：相当于 RO code
.constdata：相当于 RO data
.bss：相当于 ZI data
.data：相当于 RW data

map文件的5个组成部分说明：

程序段交叉引用关系：main调用了sys.c中的sys_stm32_clock_init函数
删除映像未使用的程序段：列出了没有用到而被删除的程序段，并统计了移除的程序段。为了更好的节省空间，我们一般在 MDK→魔术棒→C/C++选项卡里面勾选： One ELF
Section per Function。
映像符号表：描述被引用的各个符号在存储器中的存储地址、类型、大小等信息。映像符号表分为本地符号（static声明的全局变量地址和大小，c文件函数地址和static函数代码大小，汇编文件中的标号地址，作用域：限本文件）和全局符号（全局变量的地址和大小，c文件中函数的地址和代码大小，汇编文件中的标号地址，作用域：全工程）。
映像内存分布图：
映像组件大小