13.4 内存管理和接口

​ 在第11章中，我介绍了接口的内存管理的关键要素。与对象不同，接口是受管理且具有引用计数。如我所提到的，接口引用会增加所引用对象的引用计数，但您可以声明接口引用为弱引用以禁用引用计数（但仍然要求编译器为你管理引用），或者您可以使用unsafe修饰符完全禁用对特定引用的任何编译器支持。在这一节中，我们将深入探讨这个领域，展示一些在第11章中提供示例之外的额外示例。

13.4.1 关于弱引用的更多内容

​ Delphi 对接口使用的引用计数模型存在一个问题，即如果两个对象相互引用，它们将形成循环引用，并且它们的引用计数基本上永远不会降至零。弱引用提供了一种打破这些循环的机制，允许您定义一个不会增加引用计数的引用。

​ 假设两个接口使用它们的字段相互引用，而外部变量引用第一个接口。第一个对象的引用计数将为2（外部变量和第二个对象的字段），而第二个对象的引用计数为1（第一个对象的字段）。图13.4描述了这种情况。

图 13.4： 对象间的引用 对象之间的引用可以形成循环、 弱引用的原因

​ 现在，当外部变量退出作用域时，两个对象的引用计数为1；并且，由于拥有Object2的主对象Object1没有外部所有者，因此这两个对象将无限期保留在内存中。为解决这种情况，您应该打破循环引用，这是一件相当复杂的事情，因为您不知道何时执行此操作（应在最后一个外部引用超出范围时执行，但这是对象无法知道的事实）。

​ 解决这种情况以及许多类似情况的方法是使用弱引用。如前所述，弱引用是对对象的引用，不会增加其引用计数。从技术上讲，您通过对其应用[weak]attribute来定义弱引用。

注解： Attributes是第16章将介绍的Object Pascal高级语言功能。简而言之，它们是一种关于符号的添加一些运行时信息的方法，以便外部代码可以确定如何处理它。

​ 再考虑一下先前的场景，如果从第二个对象对第一个对象的引用是弱引用（见图13.5），那么当外部变量超出作用域时，两个对象都将被销毁。

​ 让我们用代码来看看这种简单情况。首先，ArcExperiments 应用程序示例声明了两个接口，一个引用另一个：

type
  IMySimpleInterface = interface
    ['{B6AB548A-55A1-4D0F-A2C5-726733C33708}']
    procedure DoSomething(BRaise: Boolean = False);
    function RefCount: Integer;
  end;
  
  IMyComplexInterface = interface
    ['{5E8F7B29-3270-44FC-B0FC-A69498DA4C20}']
    function GetSimple: IMySimpleInterface;
    function RefCount: Integer;
  end;

​ 程序的代码定义了两个实现这些接口的不同类。注意交叉引用（FOwnedBy和FSimple基于接口，其中一个被定义为弱引用）：

type
  TMySimpleClass = class(TInterfacedObject, IMySimpleInterface)
  private
    [Weak] FOwnedBy: IMyComplexInterface;
  public
    constructor Create(Owner: IMyComplexInterface);
    destructor Destroy; override;
    procedure DoSomething(BRaise: Boolean = False);
    function RefCount: Integer;
  end;

  TMyComplexClass = class(TInterfacedObject, IMyComplexInterface)
  private
    FSimple: IMySimpleInterface;
  public
    constructor Create;
    destructor Destroy; override;
    function GetSimple: IMySimpleInterface;
    function RefCount: Integer;
  end;

​ 这个“complex”类的构造函数创建了另一个类的对象：

constructor TMyComplexClass.Create;
begin
  inherited Create;
  FSimple := TMySimpleClass.Create(Self);
end;

​ 请记住，FOwnedBy字段是一个弱引用，因此它不会增加其引用对象的引用计数，在本例中，它不会增加 TMyComplexClass 的引用计数。在本例中是当前对象（Self）。鉴于此代码结构，我们可以编写：

class procedure TMyComplexClass.CreateOnly;
var
  MyComplex: IMyComplexInterface;
begin
  MyComplex := TMyComplexClass.Create;
  MyComplex.FSimple.DoSomething;
end;

​ 只要使用弱引用，这将不会导致内存泄漏。例如，使用以下代码：

var
  MyComplex: IMyComplexInterface;
begin
  MyComplex := TMyComplexClass.Create;
  Log('Complex = ' + MyComplex.RefCount.ToString);
  MyComplex.GetSimple.DoSomething(False);

​ 鉴于每个构造函数和析构函数都记录了其执行，您将得到一个类似于以下的日志：

kotlinCopy codeComplex class created
Simple class created
Complex = 1
Simple class doing something
Complex class destroyed
Simple class destroyed

​ 如果在代码中删除weak属性，你会看到一个内存泄漏，并且（在上面的代码执行中）引用计数为2而不是1。