【Godot4.2】颜色完全使用手册

概述

本篇简单汇总Godot中的颜色的构造和使用，内容包括了：

  • RGB、RGBA，HSV以及HTML16进制颜色值、颜色常量等形式构造颜色
  • 颜色的运算以及取反、插值
  • 用类型化数组、紧缩数组或PNG图片形式存储多个颜色

构造颜色

因为颜色是一种视觉元素，所以用print打印颜色值到输出窗口是比较抽象的做法。

这里我采用了HFlowContainer+ColorRect的形式，并编写一个函数show_color来动态生成ColorRect添加到HFlowContainer，来显示我们构造的颜色。

其中：

  • HFlowContainer是水平流式布局容器，添加为其一级子节点的控件将按照类似HTML文档的流式布局形式，也就是逐行从右向左排列，占满一行自动换行。
  • ColorRect也是一个专用于显示单个颜色的矩形控件

测试场景：
image.png
颜色显示函数：

# 用ColorRect显示颜色
func show_color(color:Color):
	var rect = ColorRect.new()
	rect.color = color
	rect.custom_minimum_size = Vector2(100,100)
	print(color) # 打印颜色值
	add_child(rect)

使用Color类型的构造函数构造颜色

  • 在GDScript中，颜色有专门的数据类型Color。
  • Color和int、float以及String一样，属于GDScript内置的数据类型之一，专用于构造和存储颜色数据，并提供方法进行颜色的处理。
  • Color类型提供了多种构造函数，我们可以用构造函数形式，创建Color类型的变量。
# 使用构造函数构造颜色
var c1 = Color()                    # 默认黑色
# RGB或RGBA形式
var c2 = Color(1.0,0.0,0.0)         # Color(r,g,b)
var c3 = Color(0.0,1.0,0.0,1.0)     # Color(r,g,b,a)

用show_color函数显示的效果：
image.png
可以看到和Vector2或Vector3类似，空的构造函数都会返回所有分量都为0的值。而Color()也返回R、G、B分量都是0，但不透明度为1的颜色，也就是黑色。

也就是说：

  • Vector2()=Vector2(0,0)
  • Vector3()=Vector3(0,0,0)
  • Color()=Color(0,0,0)=Color(0,0,0,1)

另外你可以使用RGBA或RGB形式构造颜色：

  • 一个Color由R、G、B、A四个通道组成，分别代表红色Red、绿色Green、蓝色Blue和不透明度Alpha。
  • 每个通道值都采用0.0到1.0之间的小数，你也可以将其理解为百分比0%～100%。
  • 在构造Color类型的时候你可以使用RGB和RGBA两种基本形式，RGB形式可以看做是固定A为1.0的RGBA。

使用全局函数Color8

除了Color类型及其构造函数，GDScript还提供了一个全局函数Color8：

Color8(r8: int, g8: int, b8: int, a8: int = 255)

8的意思就是8位，2^8=256，也就是R、G、B、A通道值的范围是从0到 255，其中A的默认值为255，也就是完全不透明。

其实Color8返回的也是Color类型。所以两者本质上没有什么区别。实际使用中Color类型的小数形式或者说百分比形式更直观一点。Color8更偏向原始的计算机定义。

var c1 = Color8(255,0,0)      # 红色
var c2 = Color8(255,0,0,127)  # 红色，不透明度约0.5

image.png

使用16进制字符串或颜色名称形式

# 字符串：16进制或颜色名(不区分大小写)
var c6 = Color("#0000ff")           # #RRGGBB
var c7 = Color("#0000ffcc")         # #RRGGBBAA
var c8 = Color("#cc0")              # #RGB
var c9 = Color("#cc0c")             # #RGBA
var c10 = Color("cc0c")             # RGBA

# 颜色名字符串形式
var c11 = Color("red")              # 颜色名字符串
var c12 = Color("red",0.5)          # 颜色名字符串+ Alpha值

# from_string方法
var c20 = Color.from_string("blue",Color.BLUE) # (颜色名，默认值)
var c21 = Color.from_string("#ccc",Color.BLUE) # (颜色名，默认值)
16进制整数形式
# 16进制整数形式
var c24 = Color.hex(0xff0000ff)  # 0xRRGGBBAA,0x为前缀，表示为16进制
var c25 = Color.hex(0x00ff00ff)  # 0xRRGGBBAA,0x为前缀，表示为16进制
16进制html颜色字符串形式
# 16进制html颜色字符串形式
var c26 = Color.html("#ccc")        # #RGB
var c27 = Color.html("#ff0000")     # #RRGGBB
var c28 = Color.html("#ff0000ee")   # #RRGGBBAA
var c29 = Color.html("ff0000ee")    # RRGGBBAA

使用颜色常量

Color类型内部定义了很多颜色常量，你可以很方便的用颜色的常量名。
你可以在《包含GODOT所有名称颜色的JSON》中获得所有颜色常量的英文名和中文名及其颜色值的信息。

# 颜色常量
var c1 = Color.YELLOW                      # Color内置常量
var c2 = Color(Color.YELLOW_GREEN,1.0)     # Color内置常量

使用HSV形式构造

除了以上的RGB形式，16进制颜色值形式，颜色常量或颜色名形式，还可以使用(h,s,v)或(h,s,v,a)形式构造颜色。

var c1 = Color.from_hsv(1,1,1,1)
var c2 = Color.from_hsv(0,1,1,1)

show_color(c1)  # (1, 0, 0, 1)
show_color(c2)  # (1, 0, 0, 1)

关于HSV颜色模式的具体内容见下文《获取HSV分量》部分。

获取比当前颜色更暗或更亮的颜色

  • 使用Color的lightened()方法，可以创建比当前颜色更亮的颜色
  • 使用Color的darkened()方法，则可以创建比当前颜色更暗的颜色
var c1 = Color.RED  
	
# 显示颜色
show_color(c1.lightened(0.8))    
show_color(c1.lightened(0.6))
show_color(c1.lightened(0.4))
show_color(c1.lightened(0.2))
show_color(c1)                   # 原始颜色
show_color(c1.darkened(0.2))
show_color(c1.darkened(0.4))
show_color(c1.darkened(0.6))
show_color(c1.darkened(0.8))

image.png

获取颜色的分量

你可以通过以下形式获取一个Color的分量：

  • r,g,b,a获取其小数形式的分量
  • r8,g8,b8,a8获取其8位形式的分量
  • 下标[0],[1],[2],[3]形式获取r,g,b,a分量
  • h,s,v获取HSV模式的分量
var c1 = Color("red")        
	
# 显示颜色
show_color(c1)  # (1, 0, 0, 1)

# 小数形式
print(c1.r)  # 1
print(c1.g)  # 0
print(c1.b)  # 0
print(c1.a)  # 1

# 8位形式
print(c1.r8)  # 255
print(c1.g8)  # 0
print(c1.b8)  # 0
print(c1.a8)  # 255

# 下标形式
print(c1[0])  # 1
print(c1[1])  # 0
print(c1[2])  # 0
print(c1[3])  # 1

获取HSV分量

HSV颜色模型

HSV是另一种构造或表示颜色的模型，你可以称其为色相-饱和度-明度模型，即：
在这里插入图片描述
其数学形式的表示，一种是圆柱体，一种是圆锥体。

  • H：色相，Hue，是围绕中心轴的角度，取值为0~360度，GDScript中将其映射到0.0~1.0范围
  • S：饱和度，Saturation，是距中心轴的距离，取值为0~100，GDScript中将其映射到0.0~1.0范围
  • V：明度，Value，是中心轴的高度，取值为0~100，GDScript中将其映射到0.0~1.0范围

HSV模型又称HSB，其中B为Brightness。

Godot中的HSV

  • ColorPicker和ColorPickerButton使用的是下图左的取色形式

  • 检视器面板的颜色类属性（包括导出变量）采用的时下图右的取色形式
    在这里插入图片描述
    可以看到两者只是将H、S、V三个参数进行了不同的组合：

  • 前者将色相H单独拎出来，饱和度S和明度V进行组合

  • 后者将明度V单独出来，将色相和饱和度进行组合

在其他一些软件，还可以看到“色环”形式的HSV取色器设计：
在这里插入图片描述

  • 其中色相H采用360度的色环形式
  • 饱和度S和明度V组合成一个正三角形且三角形顶部的顶点指向色相，对应锥形模型的切面
  • 饱和度S和明度V也可以组合成正方形，对应圆柱体模型的一个切面
360度色相映射0到1的方法

度数/360即可。
黄色在RGB/CMY色环中为60度，60/360=1/6=0.16666666…

var c1 = Color.YELLOW

print(c1.h)  # 色相 0.16666667163372
print(c1.s)  # 饱和度 1
print(c1.v)  # 亮度 1

可以看到数值非常相近。

用HSV形式构造颜色

可以用Color类型的from_hsv()方法以(h,s,v,a)形式构造颜色。

var c1 = Color.from_hsv(1,1,1,1)
var c2 = Color.from_hsv(0,1,1,1)

show_color(c1)  # (1, 0, 0, 1)
show_color(c2)  # (1, 0, 0, 1)
  • 因为0°和360°都是红色，所以用0（0/360）或1（360/360）都是可以的。

image.png

生成简易HSV360色相

for i in range(360.0):
	show_color(Color.from_hsv(i/360.0,1,1,1))

image.png

颜色的比较

两个Color类型的颜色值，可以使用==或!=进行比较，判断是否相等。

var c1 = Color(1.0,0,0)
	
print(c1 == Color.RED)  # true
print(c1 != Color.RED)  # false

判断两个颜色是否近似相等

如果你按F1搜索is_equal_approx，可以看到很多内置类型都自带了一个is_equal_approx方法，这些类型一般都是由几个分量组成。

而在@GlobalScope中也存在一个is_equal_approx方法，用于比较两个浮点数是否相近。

其他内置类型is_equal_approx方法都是在其各个分量上调用@GlobalScope的is_equal_approx方法。
image.png
根据内置文档的说法is_equal_approx的精度与比较的数字本身的大小有关，数字越小，精度要求越高，数字越大，精度要求越低。
以下是我简单进行的几组测试：

print(is_equal_approx(0.9,1.0))     # flase
print(is_equal_approx(0.99,1.0))    # flase
print(is_equal_approx(0.999,1.0))   # flase
print(is_equal_approx(0.9999,1.0))  # flase
print(is_equal_approx(0.99999,1.0)) # true

print(is_equal_approx(9,10))           # flase
print(is_equal_approx(9.9,10))         # flase
print(is_equal_approx(9.99,10))        # flase
print(is_equal_approx(9.999,10))       # flase
print(is_equal_approx(9.9999,10))      # flase
print(is_equal_approx(9.99999,10))     # true

print(is_equal_approx(9999,10000))           # flase
print(is_equal_approx(9999.9,10000))         # flase
print(is_equal_approx(9999.99,10000))        # true
print(is_equal_approx(9999.999,10000))       # true

print(is_equal_approx(999999999,1000000000)) # true

因此在使用Color类型的is_equal_approx()，判定两个颜色是否近似时，其判定为true的条件是非常严格的，就是每个分量的差值都要＜0.00001才行。

var c1 = Color(0,1,0,1)
var c2 = Color(0,0.9,0,1)
var c3 = Color(0,0.99,0,1)
var c4 = Color(0,0.999,0,1)
var c5 = Color(0,0.9999,0,1)
var c6 = Color(0,0.99999,0,1)
var c7 = Color(0,0.999999,0,1)

show_color(c1)
show_color(c2)
show_color(c3)
show_color(c4)
show_color(c5)
show_color(c6)
show_color(c7)
print(c1.is_equal_approx(c2))   # false
print(c1.is_equal_approx(c3))   # false
print(c1.is_equal_approx(c4))   # false
print(c1.is_equal_approx(c5))   # false
print(c1.is_equal_approx(c6))   # false
print(c1.is_equal_approx(c7))   # true

这种近乎变态的近似判断几乎没有实用意义，因此不如自己编写一个函数来判断两个颜色的近似。

# 判断两个颜色是否相似，精度precision可以自定义，默认0.1
func is_similar_color(color1:Color,color2:Color,precision:float = 0.1) -> bool:
	var bol:bool
	var color_d = color1-color2  # 获得颜色的差值
	var color_d_arr = []         # 存储转化为绝对值和特定精度的分量
	# 将分量转换为特定精度的小数的绝对值
	for i in range(4):
		var d_val = snapped(absf(color_d[i]),precision) # 转换为与precision小数位数一致的浮点数
		color_d_arr.append(d_val)
	
	# 比较每个分量的绝对值是否都达到精度值的要求
	if color_d_arr[0] <= precision and \
		color_d_arr[1] <= precision and \
		color_d_arr[2] <= precision and \
		color_d_arr[3] <= precision:
		bol = true
	# 或者所有有分量的差值之和小于3倍精度
	elif color_d_arr[0] + color_d_arr[1]+ color_d_arr[2] + color_d_arr[3] <= precision * 3:
		bol = true
	else:
		bol = false
	return bol

var c1 = Color(0,1,0,1)
var c2 = Color(0,0.9,0,1)
var c3 = Color(0.1,0,0,1)
var c4 = Color(0.1,0.9,0,1)
var c5 = Color(0.2,0.9,0,1)
var c6 = Color(0.1,0.9,0.1,0.9)

show_color(c1)
show_color(c2)
show_color(c3)
show_color(c4)
show_color(c5)
show_color(c6)
print(is_similar_color(c1,c2))  # true
print(is_similar_color(c1,c3))  # false
print(is_similar_color(c1,c4))  # true
print(is_similar_color(c1,c5))  # true
print(is_similar_color(c1,c6))  # true

image.png

颜色的运算

颜色运算这部分，可以完全类比颜色是一个Vector4，虽然GDScript中没有这种数据类型，但运算形式和运算性质几乎和Vector2、Vector3如出一辙。

颜色相加

var c1 = Color.AQUAMARINE           
var c2 = Color.BLUE_VIOLET

# 显示颜色
show_color(c1)     # (0.498, 1, 0.8314, 1)
show_color(c2)     # (0.5412, 0.1686, 0.8863, 1)
show_color(c1+c2)  # (1.0392, 1.1686, 1.7176, 2)

image.png
可以看到一个Color值，类似与一个四分量向量，其加法就是各个分量值相加，这里两个颜色相加的值为(1.0392, 1.1686, 1.7176, 2)，超出了Color所定义的颜色值的上限(1.0,1.0,1.0,1.0)，也就是白色，所以最终它是以白色显示。

颜色相减

与颜色相加类似，两个颜色之间也可以进行相减运算。同样是RBGA四个通道的分量相减。

var c1 = Color.AQUAMARINE           
var c2 = Color.BLUE_VIOLET

# 显示颜色
show_color(c1)     # (0.498, 1, 0.8314, 1)
show_color(c2)     # (0.5412, 0.1686, 0.8863, 1)
show_color(c1-c2)  # (-0.0431, 0.8314, -0.0549, 0)

image.png
这里因为相减后Alpha通道值为0，所以颜色变为完全透明。

颜色相乘

var c1 = Color.AQUAMARINE           
var c2 = Color.BLUE_VIOLET

# 显示颜色
show_color(c1)     # (0.498, 1, 0.8314, 1)
show_color(c2)     # (0.5412, 0.1686, 0.8863, 1)
show_color(c1*c2)  # (0.2695, 0.1686, 0.7368, 1)

image.png
CanvasItem的modulate属性就是采用了颜色的乘法。其中比较特殊的就是：

  • 白色为(1.0,1.0,1.0,1.0)，任何数乘以1都保持不变，所以任何颜色乘以白色，还是这个颜色本身。
  • 黑色为(0.0,0.0,0.0,0.0)，任何数乘以0都会变成0，所以任何颜色乘以黑色，都会变成黑色。

image.png

颜色相除

var c1 = Color.AQUAMARINE           
var c2 = Color.BLUE_VIOLET

# 显示颜色
show_color(c1)     # (0.498, 1, 0.8314, 1)
show_color(c2)     # (0.5412, 0.1686, 0.8863, 1)
show_color(c1/c2)  # (0.9203, 5.9302, 0.9381, 1)

image.png

颜色乘以整数或浮点数

var c1 = Color(0.1,0.1,0.1)
	
show_color(c1)
show_color(c1 * 0.5)  # (0.05, 0.05, 0.05, 0.5)
show_color(c1 * 1.2)  # (0.12, 0.12, 0.12, 1.2)
show_color(c1 * 2)    # (0.2, 0.2, 0.2, 2)
show_color(c1 * 0)    # (0, 0, 0, 0)

image.png
除以一个整数或浮点数类似。

颜色的混合

var yellow = Color.YELLOW  
var green = Color.GREEN  

# 显示颜色
show_color(yellow)   # (1, 1, 0, 1)
show_color(green)    # (0, 1, 0, 1)
show_color(yellow.blend(green)) # (0, 1, 0, 1)

image.png

var yellow = Color(Color.YELLOW,0.5)
var green = Color.GREEN  

# 显示颜色
show_color(yellow)  # (1, 1, 0, 0.5)
show_color(green)    # (0, 1, 0, 1)
show_color(yellow.blend(green)) # (0, 1, 0, 1)

image.png
可以看到：如果混合的第2个颜色alpha是1，也就是不带透明度，会用后一个颜色覆盖之前的颜色。

var yellow = Color(Color.YELLOW,0.5)
var green = Color(Color.GREEN,0.5)

# 显示颜色
show_color(yellow)
show_color(green)
show_color(yellow.blend(green))

image.png
只有当第2个颜色alpha小于1，也就是带透明度，才可以看到混合的效果。

获取反色

var green = Color.GREEN  
	
# 显示颜色
show_color(green)             # (0, 1, 0, 1)
show_color(green.inverted())  # (1, 0, 1, 1)

image.png
inverted()返回反色 (1-r,1-g,1-b,a)。

获取颜色的灰度和亮度

godot4.2已经删除了Color的gray()方法，但我们根据其灰度值计算原理：(r + g + b) / 3。可以自己构造一个函数进行代替

# 返回颜色的灰度值
func get_gray(color:Color) -> float:
	return (color.r + color.g + color.b)/3.0

get_luminance()返回该颜色的亮度，位于[0.0, 1.0]的范围内。可以用来确定颜色是亮色还是暗色。一般认为亮度小于0.5的颜色是暗色。

var green = Color.GREEN  
	
# 显示颜色
show_color(green)              # (0, 1, 0, 1)
print(green.get_luminance())   # 0.71520000696182
print(get_gray(green))         # 0.33333333333333

颜色插值

var green = Color.GREEN  
var red = Color.RED

# 从0%到100%cha插值
for i in range(11):
    show_color(green.lerp(red,i * 0.1)) # 显示颜色

image.png
查看输出的数据，可以看到插值的整个过程：

(0, 1, 0, 1)
(0.1, 0.9, 0, 1)
(0.2, 0.8, 0, 1)
(0.3, 0.7, 0, 1)
(0.4, 0.6, 0, 1)
(0.5, 0.5, 0, 1)
(0.6, 0.4, 0, 1)
(0.7, 0.3, 0, 1)
(0.8, 0.2, 0, 1)
(0.9, 0.1, 0, 1)
(1, 0, 0, 1)

3.5的函数linear_interpolate4.x改名为lerp。

不同颜色表示形式之间的转化

关于RGB模式：8位,16位,32位和64位色

  • RGB色彩就是常说的光学三原色，R代表Red（红色），G代表Green（绿色），B代表Blue（蓝色）。自然界中肉眼所能看到的任何色彩都可以由这三种色彩混合叠加而成，因此也称为加色模式。
  • 现代的电子显示器，包括电视、电脑、手机和平板等大都是采用了RGB颜色标准，在显示器上，是通过电子枪打在屏幕的红、绿、蓝三色发光极上来产生色彩的，电脑一般都能显示32位颜色，约有一百万种以上的颜色。
  • 在led 领域 利用三合一点阵全彩技术， 即在一个发光单元里由RGB三色晶片组成全彩像素。 随着这一技术的不断成熟，led显示技术会给人们带来更加丰富真实的色彩感受。
  • 8位深（2的8次方）意味着有256种灰度或彩色组合，16位深（2的16次方）能表现65536种可能的颜色组合，24位深能够表现约1670万种不同的颜色。
  • 32位图像所含的信息多，所以表现的图像更加细腻逼真，而16位图像和8位图像由于所含的图像信息较少，所以表现的图像画质不如32位的细腻。

—— photoshop RGB模式8位,16位,32位有什么不同?_百度知道 (baidu.com)

RGBA转ABGR、ARGB等

Color类型提供了几个颜色表示形式转化的的函数，提供RGBA转ABGR、ARGB等格式。抱歉我对ABGR、ARGB格式的使用了解较少。这里贴出内置文档源码：

var color = Color(1, 0.5, 0.2)
print(color.to_abgr32()) # 输出 4281565439
print(color.to_abgr64()) # 输出 -225178692812801
print(color.to_argb32()) # 输出 4294934323
print(color.to_argb64()) # 输出 -2147470541
print(color.to_rgba32()) # 输出 4286526463
print(color.to_rgba64()) # 输出 -140736629309441

RGBA转HTML16进制颜色字符串

var color = Color(1, 1, 1, 0.5)
var s1 = color.to_html() # 返回 "7fffffff"
var s2 = color.to_html(false) # 返回 "ffffff"

判断某个变量是否为Color类型

var color = Color(1, 1, 1, 0.5)

print(color is Color)  # true
print(typeof(color) == TYPE_COLOR)  # true

批量存储颜色

在Godot4.X中你可以用类型化数组Array[Color]形式或紧缩数组PackedColorArray来专门用于存储多个颜色。

var colors:Array[Color]
	
for i in range(360.0):
    colors.append(Color.from_hsv(i/360.0,1,1,1))

或者：

var colors:PackedColorArray
	
for i in range(360.0):
    colors.append(Color.from_hsv(i/360.0,1,1,1))

声明存储多个颜色的导出变量

通过将导出变量类型设定为Array[Color]或PackedColorArray，就可以在检视器面板设定多个颜色。

extends HFlowContainer

@export var colors:PackedColorArray

image.png

声明存储多个颜色的自定义资源

可以自定义Resource，来存储多个颜色。

# 调色板 - 存储多个颜色
@tool
class_name ColorPalette extends Resource

@export var colors:PackedColorArray

你可以在检视器面板新建和编辑ColorPalette：
image.png
或者用代码方式创建、编辑并保存

var p1 = ColorPalette.new()
p1.colors.append(Color.RED)
p1.colors.append(Color.GREEN)
p1.colors.append(Color.YELLOW)
p1.colors.append(Color.BLUE)
ResourceSaver.save(p1,"res://colors_p1.tres")

用PNG图存储调色板

利用Image类型，我们可以直接将颜色值存储到一张png或jpg等形式的图片上。

var img = Image.create(5,1,false,Image.FORMAT_RGBA8)
img.set_pixel(0,0,Color.RED)
img.set_pixel(1,0,Color.GREEN)
img.set_pixel(2,0,Color.YELLOW)
img.set_pixel(3,0,Color.BLUE)
img.set_pixel(4,0,Color.GOLD)
img.save_png("colos1.png")

输出的图片如下：
在这里插入图片描述
我们可以重新加载这张图片，然后通过get_pixel来读取其中的颜色信息。

参考资料

  • 维基百科 - HSL和HSV色彩空间
  • 百度百科 - 三原色

本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若转载，请注明出处：/a/464826.html

如若内容造成侵权/违法违规/事实不符，请联系我们进行投诉反馈qq邮箱809451989@qq.com，一经查实，立即删除！

相关文章

Vue中使用Lodash

Vue中使用Lodash

Vue中使用Lodash 前言安装Lodash引用方法vue中使用1、cloneDeep 深拷贝2、uniq 数组去重3、uniqWith 数组对象去重 isEqual 深度比对4、intersection 提取数组相同元素5、chunk 数组切分6、compact去除假值7、reject:根据条件删除指定的值8、find:查找结果的第一个值9、filter：…
阅读更多...
VsCode 配置go开发环境之下载go tools

VsCode 配置go开发环境之下载go tools

ctrl shift P 选择 go install/update tools&#xff0c;下载go tools 报错&#xff0c; 提升dial err。 将GOPROXY 和 GOSUMDB 按照如下配置&#xff0c;重启IDE即可成功下载 set GOPROXYhttps://goproxy.cn set GOSUMDBoff
阅读更多...
(18)C#采集微信群群成员列表信息-微信UI自动化(.Net)

(18)C#采集微信群群成员列表信息-微信UI自动化(.Net)

往期知识回顾 (1)C#开启探索微信自动化之路-微信UI自动化 (2)C#创建微信窗体自动化实例-微信UI自动化 (3)C#针对系统热键管理-微信UI自动化 (4)C#采集微信通讯录和联系人-微信UI自动化 (5)C#实现针对微信窗体鼠标静默点击-微信UI自动化 (6)C#搜索微信通讯录联系人-微信UI…
阅读更多...
什么是API安全性以及为什么它很重要？

什么是API安全性以及为什么它很重要？

API指的是应用程序接口&#xff08;Application Programming Interface&#xff09;&#xff0c;是一组定义和描述不同软件组件如何通信以及相互操作的规范。它允许不同的软件系统之间共享数据和功能&#xff0c;使它们能够相互连接和交互。 API可以是不同软件之间的通信桥梁&…
阅读更多...
进入docker容器中安装软件失败解，国外源慢，时间不同步，执行命令权限不够等问题解决办法

进入docker容器中安装软件失败解，国外源慢，时间不同步，执行命令权限不够等问题解决办法

进入docker容器中安装软件失败解&#xff0c;时间不同步, 国外源慢&#xff0c;执行命令权限不够 等问题解决办法 首先我进入docker容器中&#xff0c;为了安装一个软件&#xff0c;引出了很多报错问题&#xff0c;报错如下&#xff1a; 1、无法用 ifconfig 或者 ip addr 的方…
阅读更多...
HAProxy高性能负载均衡器

HAProxy高性能负载均衡器

一、HAProxy基础知识 &#xff08;一&#xff09;HAProxy概述 HAProxy是一款基于事件驱动、单进程模型设计的四层与七层负载均衡器&#xff0c;它能够在TCP/UDP层面以及HTTP(S)等应用层协议上实现高效的流量分发。HAProxy不仅适用于Web服务器负载均衡&#xff0c;还能应用于数据…
阅读更多...
vulhub中DNS域传送漏洞复现

vulhub中DNS域传送漏洞复现

DNS协议支持使用axfr类型的记录进行区域传送&#xff0c;用来解决主从同步的问题。如果管理员在配置DNS服务器的时候没有限制允许获取记录的来源&#xff0c;将会导致DNS域传送漏洞。 环境搭建 Vulhub使用Bind9来搭建dns服务器&#xff0c;但不代表只有Bind9支持AXFR记录。运行…
阅读更多...
网络通信.

网络通信.

1.物理层&#xff1a;网络通信的基础设施 运快递的公路 2.数据链路层 两个相邻的节点之间如何传输 两个集散点之间的传输 3.网络层 两个点之间的路径规划 物流公司规划快递的路径 4.传输层 两个点之间的通信&#xff08;不考虑路径规划&#xff09; 卖家发货 只考虑起点和终点 …
阅读更多...
java----网络编程（一）

java----网络编程（一）

一.什么是网络编程 用户在浏览器中&#xff0c;打开在线视频网站&#xff0c;如优酷看视频&#xff0c;实质是通过网络&#xff0c;获取到网络上的一个视频资源。 与本地打开视频文件类似&#xff0c;只是视频文件这个资源的来源是网络。所谓网络资源就是网络中获取数据。而所…
阅读更多...
SpringTask实现的任务调度与XXL-job实现的分布式任务调度【XXL-Job工作原理】

SpringTask实现的任务调度与XXL-job实现的分布式任务调度【XXL-Job工作原理】

目录 任务调度 分布式任务调度 分布式任务调度存在的问题以及解决方案 使用SpringTask实现单体服务的任务调度 XXL-job分布式任务调度系统工作原理 XXL-job系统组成 XXL-job工作原理 使用XXL-job实现分布式任务调度 配置调度中心XXL-job 登录调度中心创建执行器和任务 …
阅读更多...
安装OpenEBS，镜像总是报错ImagePullBackOff或者ErrImagePull的解决方法

安装OpenEBS，镜像总是报错ImagePullBackOff或者ErrImagePull的解决方法

按照 KubeSphere 官方文档安装 OpenEBS&#xff0c;镜像总是报错ImagePullBackOff或者ErrImagePull的解决方法 helm 有很多更换 源 的文章&#xff0c;有一些是写更换阿里云的源&#xff0c;但是阿里云的源根本没更新OpenEBS的镜像。 在网上找到1个可用的源&#xff1a; 可用的…
阅读更多...
nodejs pkg打包跨平台执行文件，带.node插件

nodejs pkg打包跨平台执行文件，带.node插件

在nodejs引入的第三方库中，大部分插件都是nodejs原生开发，使用pkg可以快速打包，生成windows、linux(ubuntu、centOS等)、麒麟系统下面执行文件。遇到了第三方插件gdal、sharp、sqlite3，在webstorm中打包生成执行文件，跨平台部署的时候会出现找不到###.node文件，需要获取部…
阅读更多...
BUUCTF-----[CISCN 2019 初赛]Love Math

BUUCTF-----[CISCN 2019 初赛]Love Math

<?php error_reporting(0); //听说你很喜欢数学&#xff0c;不知道你是否爱它胜过爱flag if(!isset($_GET[c])){show_source(__FILE__); }else{//例子 c20-1$content $_GET[c];if (strlen($content) > 80) {die("太长了不会算");}$blacklist [ , \t, \r, \n…
阅读更多...
Employing Multi-Estimations for Weakly-Supervised Semantic Segmentation

Employing Multi-Estimations for Weakly-Supervised Semantic Segmentation

eighted selective training (WST) 辅助信息 作者未提供代码
阅读更多...
《手把手教你》系列技巧篇（三十七）-java+ selenium自动化测试-日历时间控件-上篇（详解教程）

《手把手教你》系列技巧篇（三十七）-java+ selenium自动化测试-日历时间控件-上篇（详解教程）

1.简介 我们在实际工作中&#xff0c;有可能遇到有些web产品&#xff0c;网页上有一些时间选择&#xff0c;然后支持按照不同时间段范围去筛选数据。网页上日历控件一般&#xff0c;是一个文本输入框&#xff0c;鼠标点击&#xff0c;就会弹出日历界面&#xff0c;可以选择具体…
阅读更多...
x6.js 从流程图组件库中拖拽组件到画布dnd使用

x6.js 从流程图组件库中拖拽组件到画布dnd使用

上一篇已经了解到了x6.js常用功能以及使用方法。但我们使用流程图的时候还少不了一个非常重要的功能那就是拖拽组件库里的组件进来。如下图&#xff1a; 首先是布局这块&#xff0c;拖拽组件库的视图中布局无需我们去写&#xff0c;我们只需把界面搭建好。 添加组件库 1.搭建布…
阅读更多...
LeetCode 0310.最小高度树：拓扑排序秒了

LeetCode 0310.最小高度树：拓扑排序秒了

【LetMeFly】310.最小高度树&#xff1a;拓扑排序秒了 力扣题目链接&#xff1a;https://leetcode.cn/problems/minimum-height-trees/ 树是一个无向图&#xff0c;其中任何两个顶点只通过一条路径连接。 换句话说&#xff0c;一个任何没有简单环路的连通图都是一棵树。 给你…
阅读更多...
JavaScript 进阶（一）

JavaScript 进阶（一）

一、作用域 作用域&#xff08;scope&#xff09;规定了变量能够被访问的“范围”&#xff0c;离开了这个“范围”变量便不能被访问。 作用域分为&#xff1a; 局部作用域 、全局作用域。 1.1局部作用域 局部作用域分为函数作用域和块作用域。 1. 函数作用域&#xff1a; 在函数…
阅读更多...
力扣刷题Days20-151. 反转字符串中的单词(js)

力扣刷题Days20-151. 反转字符串中的单词(js)

目录 1,题目 2&#xff0c;代码 1&#xff0c;利用js函数 2&#xff0c;双指针 3&#xff0c;双指针加队列 3&#xff0c;学习与总结 1&#xff0c;正则表达式 / \s /&#xff1a; 2&#xff0c;结合使用 split 和正则表达式&#xff1a; 1,题目 给你一个字符串 s &am…
阅读更多...
[漏洞分析]Fortinet FortiNAC CVE-2022-39952简析

[漏洞分析]Fortinet FortiNAC CVE-2022-39952简析

Fortinet FortiNAC CVE-2022-39952简析 一、影响版本二、概况三、利用CVE-2022-39952四、POC 一、影响版本 FortiNAC 9.4.0 FortiNAC 9.2.0 - 9.2.5 FortiNAC 9.1.0 - 9.1.7 FortiNAC 8.3 - 8.8 二、概况 Fortinet 在其安全公告中表示&#xff0c;他们在keyUpload script…
阅读更多...
最新文章

Copyright @ 2022~2023