《汇编语言》- 读书笔记 - 第16章-直接定址表
- 16.1 描述了单元长度的标号（数据标号）
- 检测点 16.1
- 16.2 在其他段中使用数据标号
- assume
- 通过标号取地址
- 检测点 16.2
- 16.3 直接定址表（Direct Addressing Table）
- 例1
- 分析
- 代码
- 效果
- 例2
- 分析
- 代码
- 效果
- 16.4 程序入口地址的直接定址表
- 实验 16 编写包含多个功能子程序的中断例程
16.1 描述了单元长度的标号（数据标号）
数据标号可以表示地址和长度。- 更
简洁的访问内存中的数据。 数据标号是有长度的。所以它只能与长度类型匹配的寄存器搭配使用。
3.1.8位的数据对8位的寄存器
3.2.16位的数据对16位的寄存器
| 标号 | 格式 | 可用位置 | 表示 |
|---|---|---|---|
| 普通标号 | 带冒号 | 代码段 | 地址 |
| 数据标号 | 不带冒号 | 代码段、数据段 | 地址、长度 |
assume cs:code
code segment
a db 1,2,3,4,5,6,7,8
b dw 0
...
code ends
end start
标号b代表了一个内存单元，地址为 code:8，长度为word（两字节）。
| - | 内存➡️ ax | 立即数➡️内存 | 内存自增 |
|---|---|---|---|
| 指令 | mov ax,b | mov b,2 | inc b |
| 相当于 | mov ax,cs:[8] | mov word ptr cs:[8],2 | inc word ptr cs:[8] |
标号a db 1,2,3,4,5,6,7,8代表了一组字节内存单元
| - | 内存[si]➡️al | 内存[立即数]➡️al | 内存[bx+si+立即数]➡️al |
|---|---|---|---|
| 指令 | mov al,a[si] | mov al,a[3] | mov al,a[bx+si+3] |
| 相当于 | mov al,cs:0[si] | mov al,cs:0[3] | mov al,cs:0[bx+si+3] |
检测点 16.1
《汇编语言》- 读书笔记 - 各章检测点归档 - 检测点 16.1
16.2 在其他段中使用数据标号
assume
通常我们不在代码段中定义数据。
通常在数据段定义数据，为了在代码段中直接使用数据标号访问数据，
我们需要为编译器使用伪指令assume将标号所在段与一个段寄存器关联起来。
（这个关联是给编译器看的。DS还是需要我们自己设置）
assume cs:code,ds:data
data segment
a dw 1,2,3,4,5,6,7,8
data ends
code segment
start: mov ax,data
mov ds,ax
mov ax,a[0]
mov ax,4c00h
int 21h
code ends
end start
assume ds:data 和 assume es:data 对于访问内存 [] 会得到不同的段地址：
通过标号取地址
可以将标号当作数据用，此时，编译器视其地址为值。
是取 偏移地址 还是 偏移地址和段地址 取决于数据的类型：
- 偏移地址
C的类型为dw字，就只取偏移地址
data segment
a db 1,2,3,4,5,6,7,8
b dw 0
c dw a,b ; 相当于：c dw offset a offset b
data ends
- 偏移地址 + 段地址
C的类型为dd双字，就要取偏移地址和段地址
data segment
a db 1,2,3,4,5,6,7,8
b dw 0
c dd a,b ; 相当于：dw offset a,seg a,offset b,seg b
data ends
检测点 16.2
《汇编语言》- 读书笔记 - 各章检测点归档 - 检测点 16.2
16.3 直接定址表（Direct Addressing Table）
在8086汇编语言中，直接定址表通常用于存储一系列数据，并允许程序通过索引直接访问表中的特定元素。
是常用的空间换时间算法，适用于键的数量相对固定且不会频繁变化的情况。
直接定址表的好处包括：
- 快速访问：由于键直接映射到地址，因此访问速度非常快，几乎没有延迟。
- 简单性：实现直接定址表的算法相对简单，容易理解和维护。
- 预分配内存：在创建直接定址表时，可以根据预计的键数量预先分配足够的内存空间，避免了动态分配内存的开销。
例1
以十六进制的形式在屏幕中间显示给定的字节型数据。
分析
每个字节可分为高低两个4位。每4位对应一个十六进制数。 如果每4位取出来 +30h转ascii 就挺麻烦， 不如直接用数值当索引`去一块内存中直接取对应字符。
- 用
直接定址表算法更清晰和简洁
代码
assume cs:code
code segment
start: mov al,0F1h
call showbyte
mov ax,4c00h
int 21h
showbyte:
jmp short show
table db '0123456789ABCDEF' ;字符表
show:
push bx
push es
mov bx,0b800h ; 设置显存段
mov es,bx
mov ah,al
shr ah,1
shr ah,1
shr ah,1
shr ah,1 ;右移4位，ah 保留高4位的值
and al,00001111b ;高4位置0，a1 保留低4位的值
mov bl,ah
mov bh,0
mov ah,table[bx] ;高4位的值当索引，取得对应的字符
mov es:[160*12+40*2],ah
mov bl,al
mov bh,0
mov al,table[bx] ;低4位的值当索引，取得对应的字符
mov es:[160*12+40*2+2],al
pop es
pop bx
ret
code ends
end start
效果
例2
编写一个子程序，计算 sim(x)，x ∈ { 0°，30°，60°，90°，120°，150°，180}，并在屏幕中间显示计算结果。比如 sin(30) 的结果显示为“0.5”
分析
- 用
直接定址表算法提高算法性能。
table 类型是 dw
| - | ag0 | ag30 | ag60 | ag90 | ag120 | ag150 | ag180 |
|---|---|---|---|---|---|---|---|
| 值 | 0 | 0.5 | 0.866 | 1 | 0.866 | 0.5 | 0 |
索引角度/30 | 0 | 1 | 2 | 3 | 4 | 5 | 6 |
| 位置 | 1B~1C | 1D~20 | 21~26 | 27~28 | 29~2E | 2F~32 | 33~34 |
长度字节 | 2 | 4 | 6 | 2 | 6 | 4 | 2 |
代码
assume cs:code
code segment
start: mov ax,120
call showsin
mov ax,4c00h
int 21h
showsin: ; 位 置 机器码 反汇编
jmp short show ; cs:0B EB28 jmp 0035
; table
table dw ag0,ag30,ag60,ag90,ag120,ag150,ag180 ;字符串偏移地址表 cs:0d~1a
ag0 db '0',0 ;cs:1B~1C sin(0) 对应的字符串“0”
ag30 db '0.5',0 ;cs:1D~20 sin(30) 对应的字符串“0.5”
ag60 db '0.866',0 ;cs:21~26 sin(60) 对应的字符串“0.866”
ag90 db '1',0 ;cs:27~28 sin(90) 对应的字符串“1”;
ag120 db '0.866',0 ;cs:29~2E sin(120)对应的字符串“0.866”
ag150 db '0.5',0 ;cs:2F~32 sin(150)对应的字符串“0.5”
ag180 db '0',0 ;cs:33~34 sin(180)对应的字符串“0”
show:
push bx
push es
push si
mov bx,0b800h ; 设置显存段
mov es,bx
;以下用角度值/30 作为相对于 table 的偏移，取得对应的字符串的偏移地址，放在 bx 中
mov ah,0
mov bl,30
div bl
mov bl,al
mov bh,0
add bx,bx
mov bx,table[bx]
; 以下显示 sin(x) 对应的字符串
mov si,160*12+40*2
shows: mov ah,cs:[bx]
cmp ah,0
je showret
mov es:[si],ah
inc bx
add si,2
jmp short shows
showret:
pop si
pop es
pop bx
ret
code ends
end start
效果
16.4 程序入口地址的直接定址表
在直接定址表中存储子程序的地址。
| 功能 | 实现一个子程序 setscreen，为显示输出提供如下功能。1. 清屏; 2. 设置前景色; 3. 设置背景色; 4. 向上滚动一行。 |
|---|---|
参数 ah | 用 ah 寄存器传递功能号：0 表示清屏， 1 表示设置前景色， 2 表示设置背景色, 3 表示向上滚动一行; |
参数 al | 用 al 传送颜色值，(al)∈ {0,1,2,3,4,5,6,7}。用于 1、2号功能 |
| 功能 | 实现方案 |
|---|---|
| 1.清屏 | 将显存中当前屏幕中的字符设为空格符; |
| 2.设置前景色 | 设置显存中当前屏幕中处于奇地址的属性字节的第0、1、2位; |
| 3.设置背景色 | 设置显存中当前屏幕中处于奇地址的属性字节的第4、5、6位; |
| 4.又向上滚动一行 | 依次将第 n+1 行的内容复制到第n行处;最后一行为空。 |
assume cs:code
code segment
start: mov ah,3
mov al,2
call setscreen
mov ax,4c00h
int 21h
; =======================================================
; ------------------- 子程序 setscreen -----------------
; 设置显示效果
; -------------------------------------------------------
; 参数: ah 功能号：0 表示清屏，1 表示设置前景色，2 表示设置背景色, 3 表示向上滚动一行;
; 参数: al 颜色值。用于1、2号功能
; 返回: 无
; -------------------------------------------------------
setscreen:
jmp short set
table dw sub1,sub2,sub3,sub4
set:
push bx ; 备份寄存器
cmp ah,3 ; 判断功能号是否大于3
ja sret
mov bl,ah
mov bh,0
add bx,bx ; 根据 ah 中的功能号计算对应子程序在 table 表中的偏移
call word ptr table[bx]
sret: pop bx ; 还原寄存器
ret ; 返回
; -------------------- 子程序 setscreen -----------------
; =======================================================
; =======================================================
; ---------------------- 子程序 sub1 --------------------
; 清屏：; 将显存中当前屏幕中的字符设为空格符
; -------------------------------------------------------
; 参数: 无
; 返回: 无
; -------------------------------------------------------
sub1:
push bx ; 备份寄存器
push cx
push es
mov bx,0b800h
mov es,bx
mov bx,0
mov cx,2000
sub1s: mov byte ptr es:[bx],' ' ; 当前屏全设为空格
add bx,2
loop sub1s
pop es ; 备份寄存器
pop cx
pop bx
ret ; 返回
; ---------------------- 子程序 sub1 --------------------
; =======================================================
; =======================================================
; ---------------------- 子程序 sub2 --------------------
; 设置前景色：设置当前屏幕中所有奇列的第0、1、2位（前景色）
; -------------------------------------------------------
; 参数: 无
; 返回: 无
; -------------------------------------------------------
sub2:
push bx ; 备份寄存器
push cx
push es
mov bx,0b800h
mov es,bx
mov bx,1 ; 设置字符属性从 1 开始
mov cx,2000
sub2s: and byte ptr es:[bx],11111000b ; 清空前景色 0、1、2
or es:[bx],al ; 应用 al 传来的颜色值
add bx,2
loop sub2s
pop es ; 备份寄存器
pop cx
pop bx
ret ; 返回
; ---------------------- 子程序 sub2 --------------------
; =======================================================
; =======================================================
; ---------------------- 子程序 sub3 --------------------
; 设置背景色：设置当前屏幕中所有奇列的第4、5、6位（背景色）
; -------------------------------------------------------
; 参数: 无
; 返回: 无
; -------------------------------------------------------
sub3:
push bx ; 备份寄存器
push cx
push es
mov cl,4
shl al,cl
mov bx,0b800h
mov es,bx
mov bx,1 ; 设置字符属性从 1 开始
mov cx,2000
sub3s: and byte ptr es:[bx],10001111b ; 清空 4 ~ 6
or es:[bx],al ; 应用 al 传来的颜色值
add bx,2
loop sub3s
pop es ; 备份寄存器
pop cx
pop bx
ret ; 返回
; ---------------------- 子程序 sub3 --------------------
; =======================================================
; =======================================================
; ---------------------- 子程序 sub4 --------------------
; 向上滚动一行：依次将第 n+1 行的内容复制到第n行处;最后一行为空。
; -------------------------------------------------------
; 参数: 无
; 返回: 无
; -------------------------------------------------------
sub4:
push cx ; 备份寄存器
push si
push di
push es
push ds
mov si,0b800h
mov es,si
mov ds,si
mov si,160 ; ds:si 指向第 n+1 行
mov di,0 ; es:di 指向第 n 行
cld
mov cx,24 ; 共复制 24 行
sub4s: push cx
mov cx,160
rep movsb ; 复制
pop cx
loop sub4s
mov cx,80
mov si,0
sub4s1:mov byte ptr [160*24+si],' '
add si,2
loop sub4s1
pop ds ; 备份寄存器
pop es
pop di
pop si
pop cx
ret ; 返回
; ---------------------- 子程序 sub4 --------------------
; =======================================================
code ends
end start
实验 16 编写包含多个功能子程序的中断例程
《汇编语言》- 读书笔记 - 第16章-实验16 编写包含多个功能子程序的中断例程
