Windows系统x86机器安装龙芯（loongarch64）3A5000虚拟机系统详细教程

本次介绍在window系统x86机器上安装loongarch64系统的详细教程。

1.安装环境准备。

首先，你得有台电脑。

配置别太差，至少4核8G内存，安装window10或者11都行（为啥不能是Window7，你要用也不是不行，你先解决win7补丁更新问题）。

准备虚拟机工具软件QUME。

官网下载地址：QEMU for Windows – Installers (64 bit)，选择最新版本下载即可。

准备 QEMU UEFI 固件文件。

下载地址：https://mirrors.pku.edu.cn/loongarch/archlinux/images/QEMU_EFI_8.0.fd

准备系统安装镜像。

下载地址：北京大学开源镜像站

镜像名称：archlinux-2023.12.30-loong64.iso

安装QUEM工具。

双击安装下载的 qemu-w64-setup-20231224.exe 文件。

选择您的安装路径，路径中不要有中文。记住这个路径，后面配置环境要用。

然后install，直到完成。

继续配置系统的环境变量：

打开环境变量

找到 path

添加您安装的路径(我选择的是D:\QEMU)，这里选择您自己安装的目录：

2.安装文件及脚本准备。

选择您需要保存虚拟机文件的地方，不能有中文路径。

我选择的保存的木兰是： F:\VM\Test_uos_loongarch64

将下载的 QEMU UEFI 固件文件复制进文件夹中。

创建启动批处理文件：

将如下代码复制进去，然后保存：

@echo off
echo.
echo ---------------注意事项---------------
echo      1.路径中不要又中文。
echo      2.文件名称请勿取中文。
echo.
echo ---------------开始执行脚本---------------
echo.
echo 当前路径：请检查此路径是否包含中文。
echo      %CD%      
echo.
set efi_path=""
for /f "tokens=*" %%a in ('dir /b %CD%') do (
  for %%I in (%%a) do (
	if %%~xI == .qcow2 (
		set img_path=%%a
	) else if %%~xI == .fd (
		set efi_path=%%a
	)
  )
)

if %efi_path% == "" (
	echo       未检索到配置文件，请检查后再试！
	echo.
	goto :over_err
)

echo 检索到配置文件：%efi_path%
:input_img_name
set /p img_name=请输入镜像名称(请输入英文或数字)：
:remove_blank_img
if "%img_name:~0,1%"==" " (
	set "img_name=%img_name:~1%"
	goto :remove_blank_img
)
if "%img_name%" == "" (
	echo       输入的文件名错误，请重新输入！
	echo.
	goto :input_img_name
)
echo.
:input_img_size
set /p img_size=请输入镜像大小/GB：
:remove_blank_size
if "%img_size:~0,1%"==" " (
	set "img_size=%img_size:~1%"
	goto :remove_blank_size
)
if %img_size% == "" (
	echo       输入的文件大小错误，请重新输入！
	echo.
	goto :input_img_size
)

set /a check_size=%img_size%
if %check_size% GTR 0 (
	echo 镜像大小%img_size%/GB.
) else (
	echo       输入的文件大小错误，请重新输入！
	echo.
	goto :input_img_size
)

echo.
echo 即将创建镜像:%img_name%.qcow2
echo.
qemu-img.exe create -f raw %CD%\%img_name%.qcow2 %img_size%G
echo.
if EXIST %CD%/%img_name%.qcow2 (
	echo       生成文件成功：%CD%\%img_name%.qcow2
	echo.
) else (
	echo       生成镜像文件失败，请检查后再试！
	echo.
	goto :over_err
)

echo.
echo ----------是否开始启动安装----------
echo ---------------1.启动安装---------------
echo ---------------2.结束脚本---------------
echo.

:input_select_go
set /p select_num=请输入你的选择：
if %select_num% == 1 (
	echo       启动安装！
	echo.
)else if %select_num% == 2 (
	echo       结束脚本！
	echo.
	goto :over_err
)else (
	echo       选择错误，请重新输入！
	echo.
	goto :input_select_go
)

:input_isoPath_go
set isoPath=""
for /f "delims=" %%a in ('mshta "%~f0"') do SET isoPath=%%a
if "%isoPath%" == "" (
	echo       选择文件错误，请重新选择！
	echo.
	goto :input_isoPath_go
)
set sub_name=.iso
setlocal EnableDelayedExpansion
if "x!isoPath:%sub_name%=!"=="x%isoPath%" (
	echo       选择文件错误，请重新选择！
	echo.
	goto :input_isoPath_go
)
echo       选择镜像:%isoPath%
echo.
echo --------------执行安装程序中，请勿关闭--------------

qemu-system-loongarch64 ^
    -m 8G ^
    -cpu la464-loongarch-cpu ^
    -machine virt ^
    -smp 4 ^
    -bios %efi_path% ^
    -serial stdio ^
    -device VGA ^
    -net nic -net user ^
    -device nec-usb-xhci,id=xhci,addr=0x1b ^
    -device usb-tablet,id=tablet,bus=xhci.0,port=1 ^
    -device usb-kbd,id=keyboard,bus=xhci.0,port=2 ^
    -hda %CD%\%img_name%.qcow2 ^
    -cdrom %isoPath% ^
    -boot once=d
echo --------------结束安装，下一次启动请执行 start.bat --------------
:over_err
pause



<input type=file id=f>
<script>
f.click();new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(f.value);close();
</script>

修改文件后缀为.bat

如果未显示后缀，则需要设置一下即可：

选择是修改完成。

3.开始执行安装脚本。

双击 create_install.bat 执行脚本。

如果cmd出现乱码情况，则是编码问题。

如图：

则需要转下编码，安装 notepad++ 工具，然后打开文件：

然后点击编码=>转换为ANSI码保存即可：

然后再次双击 create_install.bat 执行脚本：

输入生成的系统名称：英文或数字

比如我输入：loongarch64

输入生成的系统大小：建议系统都必须大于等于 60 G

比如我输入的：66

然后选择输入： 1

启动安装，选择您刚刚下载的.iso的 loongarch64 镜像文件。

然后确定等待安装，选择第一个，确定 Enter ，不要关闭命令窗口。

等待安装界面，挺慢的。。。。到这个界面，开始安装。

选择 磁盘配置

然后选择 使用最佳的默认分区布局

然后选择第二个按 TAB 键选择

然后选择 ext4 模式

选择是（默认）

继续，选择 Root 密码

输入您要设置的root密码：

再次输入确认：

继续，选择 用户账户：

选择 添加一个用户：

输入要添加的用户名：

输入新建用户的密码：

再次输入密码：

选择 是（默认） 设置为超级用户：

选择 确认并退出：

继续选择音频：

选择 Pulseaudio：

继续选择 网络配置：

选择 将 ISO 中的网络配置复制到安装中

继续选择时区：

输入 “/” ，然后输入 shanghai 然后选择上海

然后选择安装：

然后按 Enter 继续：

等待安装..........

您是否想要 chroot 到新创建的系统内以进行安装后的配置？

选择 是（默认）：

然后安装完成：

安装完成后，直接关闭cmd命令窗口或者直接关闭 QEMU窗口。

或者

5.安装完成后，启动系统脚本。

在保存目录下新建 start.txt 文件。

打开txt文件，并复制粘贴以下代码模块：

@echo off
echo.
setlocal EnableDelayedExpansion
echo ----------开始检索配置文件----------
set img_path=""
set efi_path=""
for /f "tokens=*" %%a in ('dir /b %CD%') do (
  for %%I in (%%a) do (
	if %%~xI == .qcow2 (
		set img_path=%%a
	) else if %%~xI == .fd (
		set efi_path=%%a
	)
  )
)

if %efi_path% == "" (
	echo       未检索到配置文件，请检查后再试！
	echo.
	goto :over_err
)

echo 检索到配置文件：%efi_path%

if %img_path% == "" (
	echo       未检索到镜像文件，请检查后再试！
	echo.
	goto :over_err
)
echo 检索到镜像文件：%img_path%

echo 启动中，请勿关闭..！

qemu-system-loongarch64 ^
    -m 4G ^
    -cpu la464-loongarch-cpu ^
    -machine virt ^
    -smp 4 ^
    -bios %efi_path% ^
    -serial stdio ^
    -device VGA ^
    -net user,hostfwd=tcp::2222-:22 -net nic ^
    -device nec-usb-xhci,id=xhci,addr=0x1b ^
    -device usb-tablet,id=tablet,bus=xhci.0,port=1 ^
    -device usb-kbd,id=keyboard,bus=xhci.0,port=2 ^
    -hda %img_path%



:over_err
pause

保存后，修改后缀未.bat文件。

然后双击 start.bat 执行启动：

同理，如果出现cmd乱码，请转下编码，安装 notepad++ 工具，然后打开文件，然后点击编码=>转换为ANSI码保存即可。

启动成功界面：

然后输入 root + 密码登陆。

6.打开ssh服务，设置ssh开机启动。

首先安装 ssh 环境：

sudo pacman -Sy net-tools

sudo pacman -S openssh

输入 Y 安装：

查看ssh状态：

systemctl status sshd.service

启动ssh：

systemctl start sshd

设置ssh开机启动：

systemctl enable sshd.service

初始环境应该未安装vim命令：

sudo pacman -S vim

开启ssh的root登录权限：

sudo vim /etc/ssh/sshd_comfig

vim操作命令，我不多说，需要自己百度，修改完成后，保存。

然后重启ssh服务：

systemctl restart sshd

7.使用工具连接ssh。

启动您的ssh连接工具。

输入地址 127.0.0.1 端口 2222 因为在脚本中，本地2222端口映射到了虚拟机22端口。

输入账号 + 密码

连接成功界面：

————————————————

8.安装图形界面。

执行安装一些常用软件命令和图像界面：

sudo pacman -Sy wget vim git curl base linux linux-firmware base-devel zsh fish grub efibootmgr xfce4 xfce4-goodies lightdm neofetch dosfstools exfatprogs lightdm-gtk-greeter noto-fonts-cjk noto-fonts-emoji btrfs-progs xfsprogs f2fs-tools xfsprogs networkmanager nano fcitx5 fcitx5-configtool fcitx5-chinese-addons

默认全部选定Enter（有输入Y 的地方输入Y）：

安装完成后，设置默认启动图形界面：

systemctl enable lightdm.service
systemctl enable NetworkManager.service

然后。输入 reboot 重启：重启后，登陆root 或者你创建的账户都行

登陆成功，进入图形化界面：