CAD-autolisp（二）——选择集、命令行设置对话框、符号表

一、选择集

定义：批量选择出目标图元，ssget函数，结果是个图元的集合，多次加入相同元素，集合不变，多次删除相同元素，集合只执行第一次

1.1 选择集的创建

ssget函数三种选择模式：
- C（crossing）：等同鼠标点选右下角向左上角划区域
- W（window）：等同鼠标点选左上角向右下角划区域
- F（fence）:与点表所确定的折线相交的所有对象
检验选择集包含的图元数：(sslength 选择集变量名)，变量名如下代码的ss1等

代码示例

;基础使用：过滤并将框选的所有图元创建成一个选择集
(setq ss1 (ssget "c" '(100 0) '(0 100)))
(setq ss2 (ssget "w" '(0 100) '(100 0)))
(setq ss3 (ssget "f" (list '(100 0) '(0 100) '(100 100))))
;全图过滤出指定图元
;过滤出并将全图中的圆创建成一个选择集ss4返回：<Selection set:164>
(setq ss4 (ssget "x" (list (cons 0 "circle"))))
;多过滤条件
(setq ss5 (ssget "x" (list (cons 0 "circle") (cons 410 "Model"))))
;带比较符过滤:全图过滤圆，且圆半径（组码40）不小于（组码-4）10.0
(setq ss6 (ssget "x" (list (cons 0 "circle") (cons -4 ">=") (cons 40 10.0))))

动态选择c或w模式

;屏幕上点选两个点，根据两个点的相对位置自动选择模式
(setq p1 (getpoint))
;以p1为基点，拉虚线框
(setq p2 (getcorner p1))
(if (> (car p1) (car p2))
  (setq ss7 (ssget "c" p1 p2))
  (setq ss7 (ssget "w" p1 p2))
  )

1.2 选择集的编辑

从选择集增删图元

(setq ent1 (car(entsel)))

;创建一个空的选择集
(setq ss1 (ssadd))
;将图元ent1增加到已有选择集ss1中，直接修改原ss1
(ssadd ent1 ss1)	

;最内侧括号创建一个只包含ent1的选择集，每次运行都创建一个新的
(setq ss2 (ssadd ent1))	

;从选择集删除一个图元，直接修改原ss2
;若图元ent1不存在于ss2中，返回nil
;若图元ent1存在于ss2中，返回ss2
(ssdel ent1 ss2)

判断图元在选择集中

;如果不存在，返回nil
;如果存在，返回ent1的图元名
(ssmemb ent1 ss1)

选择选择集中的某个图元

;选择选择集ss1第一个图元，常配合循环语句遍历选择集
(setq ent1 (ssname ss1 0))

选择集内总共多少个元素

;常在while中作为循环中止条件，内括号返回选择集的数目
(setq length (sslength ss1))

1.3 操作选择集

实现将框选中的圆放大十倍

(defun c:demo1 ()
  ;实现框选确定选择集
  (print "请框选图元")
  (setq p1 (getpoint))
  (setq p2 (getcorner p1))
  (if (> (car p1) (car p2))
    (setq ss1 (ssget "c" p1 p2))
    (setq ss1 (ssget "w" p1 p2))
  )
  ;设置循环初始变量
  (setq n 0)
  (setq ss1_length (sslength ss1))
  ;循环遍历选择集中的每个元素，并修改
  (while (< n ss1_length)
    ;依序提取选择集中的某个图元
    (setq ent_name (ssname ss1 n))
    (setq ent_list (entget ent_name))
    (setq ent_type (cdr (assoc 0 ent_list)))

	;只修改圆
    (if	(= ent_type "CIRCLE")
      (progn
        ;提取圆，并修改圆半径（放大10倍）
	    (setq old_r (assoc 40 ent_list))
	    (setq new_r (cons 40 (* 10.0 (cdr old_r))))
	    (setq new_ent_list (subst new_r old_r ent_list))
	    (entmod new_ent_list)
      )
    )
    ;循环跳出条件
    (setq n (+ 1 n))
  )
  ;函数最后返回值
  (print)
)

二、命令行设置对话框

2.1 设置图层

方式1：常规对话框编辑图层（命令行输入layer会调出）
方式2：命令行输入：-layer

方式3：lisp代码实现

;生成图层，并使此图层为当前图层，末尾“”模仿enter功能
(command "layer" "m" "图层1" "")

2.2 加载线型

方式1：常规线型对话框（命令行输入linetype会调出）
方式2：命令行输入：-linetype

方式3：lisp代码实现

;从acad.lin文件中加载线型dashed并修改当前活动图层线型（图层默认线型不变）
(command "linetype" "l" "dashed" "acad.lin" "" "")

2.3 设置字体样式

字体样式：指定了中英文字体文件、倾斜、长宽比，用于绘图中在文字和标注中指定
字体：包含系统字体和cad字体，分别放置于C:\Windows\Fonts，C:\Program Files\Autodesk\AutoCAD 2020\Fonts文件夹下，安装插件如天正等，会在工具->选项->文件->支持文件搜索路径里包含，此处字体也会自动被搜索并加载
方式1：常规对话框（命令行输入style会调出）
方式2：命令行输入：-style

方式3：lisp代码实现

;对应选项看方式2
(command "style" "yangshi2" "tssdeng.shx,hztxt.shx" "" "" "" "" "" "")

2.4 设置标注样式（了解即可）

方式1：常规对话框（命令行输入dimstyle会调出）

方式2：命令行输入：-dimstyle

命令:  -DIMSTYLE
当前标注样式: STANDARD   注释性: 否
输入标注样式选项
[注释性(AN)/保存(S)/恢复(R)/状态(ST)/变量(V)/应用(A)/?] <恢复>: ST
DIMASO      关                    创建标注对象
DIMSTYLE    STANDARD             当前标注样式 (只读)
DIMADEC     0                    角度小数位数
DIMALT      关                    选定的换算单位
DIMALTD     2                    换算单位小数位数
DIMALTF     25                   换算单位比例因子
DIMALTMZF   100                  公制标注的换算辅零因子
...

标注样式修改：此处只能显示跟标注样式相关的系统变量，修改见方式3

方式3：lisp代码实现
```
;系统变量的获取（获取标注文字的前后缀）
(setq dimpost_old (getvar "dimpost"))

;系统变量的设置
(setvar "dimpost" "前缀：<>：后缀")
```
系统变量：cad中会有一大批固定的全局的系统变量名，通过以上方式获取与修改，针对某一个cad文件的所有元素生效

三、符号表

3.1 简介

符号表：通常图元的属性联合列表不能表示图元的所有信息，符号表则会存储有共性的属性集合供图元调用

九大符号表

符号表名	全称	lisp缩写	符号表名	全称	lisp缩写
块表	BlockTable	block	线型表	LinetypeTable	ltype
尺寸标注样式表	DimStyleTable	dimstyle	文字样式表	TextStyleTable	style
层表	LayerTable	layer	视口表	ViewportTable	vport
用户坐标系表	UCSTable	ucs	视图表	ViewTable	view
应用程序注册表	RegAppTable	appid

3.2 符号表查找

以层表为例

;查找层表首元素(t为查找第一个)
(setq layer_1 (tblnext "layer" T))
;多次运行tblnext会顺序查找并返回每一个
(setq layer_1 (tblnext "layer"))
;返回：((0 . "LAYER") (2 . "Defpoints") (70 . 0) (62 . 7) (6 . "Continuous"))

;图层名查找：查找名字为0的图层，不存在返回nil
(setq layer_3 (tblsearch "layer" "0"))
;返回：((0 . "LAYER") (2 . "0") (70 . 0) (62 . 7) (6 . "Continuous"))

;图层的详细信息，并将返回值包装成图元
(setq layer_4 (tblobjname "layer" "0"))
;返回：<图元名: 1eec337b900>
(entget layer_4)
;返回：((-1 . <图元名: 1eec337b900>) (0 . "LAYER") (5 . "10") (102 . "{ACAD_XDICTIONARY") 
;(360 . <图元名: 1eea9fee240>) (102 . "}") (330 . <图元名: 1eec337b820>) 
;(100 . "AcDbSymbolTableRecord") (100 . "AcDbLayerTableRecord") (2 . "0") (70 . 0) 	
;(62 . 7) (6 . "Continuous") (290 . 1) (370 . -3) (390 . <图元名: 1eec337b8f0>) 
;(347 . <图元名: 1eec337bee0>) (348 . <图元名: 0>))