通达信KDJ多周期共振指标选股公式，日周月金叉共振

KDJ多周期共振指标基于多个时间周期之间的共振关系来判断股票价格的变化趋势，在不同的周期上，KDJ会呈现出类似的波动形态，当这些波动形态在不同周期上发生共振时，可能会产生较为明显的价格趋势。

具体来说，多周期共振通常选择三个时间周期，分别为短期、中期和长期。在这些时间周期上，分别计算出KDJ，并观察它们之间的共振关系，如果多个周期的KDJ都显示出类似的波动形态，那么就说明这些周期之间存在共振。

在前面的文章《MACD多周期共振指标公式，日周月共振》中，介绍了MACD日周月金叉共振，公式引用了周线、月线的数据。文章最后也说了，虽然#DAY、#WEEK、#MONTH没有被定义为未来函数，但却隐含了未来的信息，因此信号可能漂移，特别是周初、月初产生的信号，这样信号的真实性大打折扣。本文用日线周期参数的5倍、30倍来代替周线KDJ、月线KDJ，虽然不能完全代替也不一定准确，但是至少信号不会漂移了。

一、KDJ多周期共振指标副图

思路：日线KDJ使用默认参数9日；周线KDJ使用日线参数的5倍，即45日；月线KDJ使用30倍，即270日。本文公式只用KDJ中的K线，D、J没有使用，所以没有写出来。

N:=9;

M:=3;

HH1:=HHV(C,N);

LL1:=LLV(C,N);

RSV1:=(C-LL1)/(HH1-LL1)*100;

K1:SMA(RSV1,M,1);

HH2:=HHV(C,N*5);

LL2:=LLV(C,N*5);

RSV2:=(C-LL2)/(HH2-LL2)*100;

K2:SMA(RSV2,M,1);

HH3:=HHV(C,N*30);

LL3:=LLV(C,N*30);

RSV3:=(C-LL3)/(HH3-LL3)*100;

K3:SMA(RSV3,M,1);

二、KDJ多周期共振指标主图（日周月金叉共振）

思路：KDJ只用到日周月KDJ的K线，A1条件是日K和周K金叉，A2条件是日K和月K金叉，A3条件是周K和月K金叉，A4是日K、周K、月K没有金叉，但是从底部起来的情况。

N:=9;

M:=3;

HH1:=HHV(C,N);

LL1:=LLV(C,N);

RSV1:=(C-LL1)/(HH1-LL1)*100;

K1:=SMA(RSV1,M,1);

HH2:=HHV(C,N*5);

LL2:=LLV(C,N*5);

RSV2:=(C-LL2)/(HH2-LL2)*100;

K2:=SMA(RSV2,M,1);

HH3:=HHV(C,N*30);

LL3:=LLV(C,N*30);

RSV3:=(C-LL3)/(HH3-LL3)*100;

K3:=SMA(RSV3,M,1);

A1:=CROSS(K1,K2) AND K1<25 AND K3<25;

A2:=CROSS(K1,K3) AND K1<25 AND K2<25;

A3:=CROSS(K2,K3) AND K1<25 AND K2<25;

TJ1:=K1>REF(K1,1) AND K2>REF(K2,1) AND K3>REF(K3,1);

TJ2:=K1<25 AND REF(K1,1)<15 AND K2<10 AND K3<5;

TJ3:=C>REF(C,1);

A4:=FILTER(TJ1 AND TJ2 AND TJ3,5);

XG:=A1 OR A2 OR A3 OR A4;

STICKLINE(XG,H,L,0,1),COLORYELLOW;

STICKLINE(XG,C,O,3,0),COLOR117777;

STICKLINE(XG,C,O,2.5,0),COLOR119999;

STICKLINE(XG,C,O,2,0),COLOR11BBBB;

STICKLINE(XG,C,O,1.5,0),COLOR11DDDD;

STICKLINE(XG,C,O,1,0),COLOR44FFFF;

DRAWICON(XG,L,11);

三、KDJ多周期共振选股公式（日周月金叉共振）

N:=9;

M:=3;

HH1:=HHV(C,N);

LL1:=LLV(C,N);

RSV1:=(C-LL1)/(HH1-LL1)*100;

K1:=SMA(RSV1,M,1);

HH2:=HHV(C,N*5);

LL2:=LLV(C,N*5);

RSV2:=(C-LL2)/(HH2-LL2)*100;

K2:=SMA(RSV2,M,1);

HH3:=HHV(C,N*30);

LL3:=LLV(C,N*30);

RSV3:=(C-LL3)/(HH3-LL3)*100;

K3:=SMA(RSV3,M,1);

A1:=CROSS(K1,K2) AND K1<25 AND K3<25;

A2:=CROSS(K1,K3) AND K1<25 AND K2<25;

A3:=CROSS(K2,K3) AND K1<25 AND K2<25;

TJ1:=K1>REF(K1,1) AND K2>REF(K2,1) AND K3>REF(K3,1);

TJ2:=K1<25 AND REF(K1,1)<15 AND K2<10 AND K3<5;

TJ3:=C>REF(C,1);

A4:=FILTER(TJ1 AND TJ2 AND TJ3,5);

XG:A1 OR A2 OR A3 OR A4;