ENVI IDL：如何解析XML文件（以Landsat9-MTL.xml文件为例）

01 前言

我们原本是打算对Landsat9文件进行辐射定标，但是辐射定标的参数在MTL文件中，从文件中查看参数直接复制到IDL中固然可行，但是当我们对Landsat9文件进行批量辐射定标时，这种方法就将失效了。因此我们需要自动从MTL文件中读取相关参数，这里的相关参数实际上只包含两个参数（对于一个波段），一个是比例系数，一个是偏置量。

对于Landsat9，给出三种MTL形式：
在这里插入图片描述
这里我们只讨论txt文本文件和XML文件的解析和提取。

02 通过XML文件获取定标参数

需要使用到IDL的IDLffXMLDOMDocument类，以及类的方法getelementsbytagname,getfirstchild,GetNodeValue。

getelementsbytagname方法通过指定标签名得到满足要求的所有标签（类似列表形式返回：IDLffXMLDOMNodeList）；
getfirstchild获取节点的第一个子节点；
GetNodeValue获取节点的值；

由于getelementsbytagname方法获取返回的值是一个类似列表的形式，当我们指定的标签名在XML文件中唯一时，那么实际上列表元素仅有一个元素，需要通过.item(0)取出第一个元素（其依旧是一个对象）。

由于我们的定标参数类似下方：
在这里插入图片描述

但是需要注意，在另外一个标签也有相同节点名称：

在这里插入图片描述

上面有两个辐射定标的参数，第一个是Level2级别的辐射定标，最终获取的是地表反射率或者地表温度（我们使用这个）；而第二个是用于级别 1（L1）的辐射定标，即将传感器捕获的原始数字数据转换为辐射亮度值。因此，我们需要进行两次getelementsbytagname方法，第一次是获取到节点LEVEL2_SURFACE_REFLECTANCE_PARAMETERS，再用一次该方法从该节点下检索各个满足要求的子节点（各个波段的比例系数和偏置量节点）。

接着从获取的指定子节点中得到所有值。

所以我们的代码应该这么写：

pro L9_C2_calibration
    ; 准备
    xml_path = 'D:\Objects\JuniorFallTerm\IDLProgram\Experiments\ExperimentalData\Week8\LC09_L2SP_130039_20220311_20220314_02_T1_MTL.xml'
    xml = IDLffXMLDOMDocument(filename=xml_path)
    
    ; 获取level2
    level2 = xml.getelementsbytagname('LEVEL2_SURFACE_REFLECTANCE_PARAMETERS')
    level2 = level2.item(0)
    b1 = level2.getelementsbytagname('REFLECTANCE_MULT_BAND_1')
    b1 = b1.item(0)
    print, double((b1.getfirstchild()).getnodevalue())
    
    ; 销毁对象
    obj_destroy, b1
    obj_destroy, level2
    obj_destroy, xml
end

输出结果：

在这里插入图片描述

（PS：说实话，IDL的XML对象真的不好用，太底层了，不如python，但是好处就是你可以更自由的自己写一些高级函数进行封装得到自己想要的方法）

封装了一下，函数如下：

;+
;   函数用途:
;       用于获取指定路径节点的值
;   函数参数:
;       xml_path: xml文件的路径
;       tags_name: 各个节点的名称(数组形式), 按父-子顺序排列
;-
function xml_get_value, xml_path, tags_name
    xml = idlffxmldomdocument(filename=xml_path)  ; 实例化一个XML对象
    
    cur_tag = xml
    foreach tag_name, tags_name do begin
        cur_tag = cur_tag.getelementsbytagname(tag_name)
        cur_tag = cur_tag.item(0)
    endforeach
    
    return, (cur_tag.getfirstchild()).getnodevalue()
end

如果你的节点相对路径如下：

LEVEL2_SURFACE_REFLECTANCE_PARAMETERS\REFLECTANCE_MAXIMUM_BAND_1
即：
在这里插入图片描述
那么获取值如下：

a = xml_get_value(xml_path, ['LEVEL2_SURFACE_REFLECTANCE_PARAMETERS', 'REFLECTANCE_MULT_BAND_1'])
print, a

在这里插入图片描述

但是需要注意，我并没有设置任何错误机制，如果你的路径错误或者不正确等问题会导致返回值为NULL甚至直接报错；另外需要注意，我这里假定所有节点在其父节点中唯一，也就是不考虑父节点下存在多个相同名称的子节点。另外确保你的相对路径唯一，如果你仅仅传入[REFLECTANCE_MAXIMUM_BAND_1]而非上述形式，那么通过前文知，多个标签Tag下存在该节点名称，那么函数会自动取第一个匹配的值。

03 通过文本文件获取定标参数

这就是通过字符串截取等方式去取值，这里就是拿各种字符串操作函数来回折腾，总体思路还是前面如此。这里给出代码：

    ; 准备
    txt_path = 'D:\Objects\JuniorFallTerm\IDLProgram\Experiments\ExperimentalData\Week8\LC09_L2SP_130039_20220311_20220314_02_T1_MTL.txt'
    
    openr, 1, txt_path
    txt_content = strarr(file_lines(txt_path))
    readf, 1, txt_content
    level2_pos = where(strmatch(txt_content, '*LEVEL2_SURFACE_REFLECTANCE_PARAMETERS*'))
    calibration_content = txt_content[level2_pos[0]:level2_pos[1]]
    band_sc_pos = where(strmatch(calibration_content, '*REFLECTANCE_MULT_BAND_1*'))
    band_sc = (strsplit(calibration_content[band_sc_pos], '=', /extract))[-1]
    print, band_sc
    free_lun, 1

运行结果如下：

在这里插入图片描述

注意，上述两种方法得到的结果均为字符串，需要转化为double等数值类型。

当然，其实还有其他方法，例如在IDL中调用python模块（XML内置模块），前提是你安装python解释器。这里也贴出代码：

ET = python.import('xml.etree.ElementTree')
tree = ET.parse(xml_path)
root = tree.getroot()
finds = root.find('./LEVEL2_SURFACE_REFLECTANCE_PARAMETERS/REFLECTANCE_MULT_BAND_1')
print, finds.text

输出结果：

在这里插入图片描述

最后贴一个对Landsat9各个波段辐射定标的完整代码（取定标参数使用方法1）：

; @Author	: ChaoQiezi
; @Time		: 2023年11月11日-上午10:24:06
; @Email	: chaoqiezi.one@qq.com

; 该程序用于 对Landsat9 C2(第二版次算法)的一级产品进行辐射定标并输出为TIFF文件

;+
;   函数用途:
;       用于获取指定路径节点的值
;   函数参数:
;       xml_path: xml文件的路径
;       tags_name: 各个节点的名称(数组形式), 按父-子顺序排列
;-
function xml_get_value, xml_path, tags_name, double=double
    xml = idlffxmldomdocument(filename=xml_path)  ; 实例化一个XML对象
    
    cur_tag = xml
    foreach tag_name, tags_name do begin
        cur_tag = cur_tag.getelementsbytagname(tag_name)
        cur_tag = cur_tag.item(0)
    endforeach
    
    value = (cur_tag.getfirstchild()).getnodevalue()
    if keyword_set(double) then return, double(value)
    
    return, value
end

pro L9_C2_calibration
    ; 准备
    in_dir = 'D:\Objects\JuniorFallTerm\IDLProgram\Experiments\ExperimentalData\Week8\'
    out_dir = in_dir + 'out_me\'
    if ~file_test(out_dir, /directory) then file_mkdir, out_dir
    xml_path = in_dir + 'LC09_L2SP_130039_20220311_20220314_02_T1_MTL.xml'
    level2_name = 'LEVEL2_SURFACE_REFLECTANCE_PARAMETERS'
    mult_name = 'REFLECTANCE_MULT_BAND_'
    add_name = 'REFLECTANCE_ADD_BAND_'
    img_wildcard = '*T1_SR_B'
    
    for band_ix = 1, 7 do begin
        cur_mult_name = mult_name + strtrim(band_ix, 1)
        cur_add_name = add_name + strtrim(band_ix, 1)
        cur_img_name = img_wildcard + strtrim(band_ix, 1) + '.tif'
        scale = xml_get_value(xml_path, [level2_name, cur_mult_name], /double)
        add = xml_get_value(xml_path, [level2_name, cur_add_name], /double)
        
        ; 读取影像文件和定标
        cur_img_path = (file_search(in_dir+cur_img_name))[0]
        cur_img = double(read_tiff(cur_img_path, geotiff=geo_info, dot_range=range))
        cur_img[where(cur_img eq 0.0, /null)] = !values.F_NAN
        cur_img = cur_img * scale + add
        
        ; 输出
        cur_out_path = out_dir + file_basename(cur_img_path)
        write_tiff, cur_out_path, cur_img, geotiff=geo_info, /double
    endfor    
end